Localizador sale de la región de la gráfica

Question

Cuando ejecuto el siguiente código

pMin = {-3, -3}; 
pMax = {3, 3}; 
range = {pMin, pMax}; 
Manipulate[ 
GraphicsGrid[ 
    { 
    {Graphics[Locator[p], PlotRange -> range]}, 
    {Graphics[Line[{{0, 0}, p}]]} 
    }, Frame -> All 
    ], 
{{p, {1, 1}}, Locator} 
] 

espero que el control de localizador para estar dentro de los límites de la primera gráfica, pero en su lugar se puede mover alrededor toda la región GraphicsGrid. ¿Hay un error en mi código?

También probé

{{p, {1, 1}}, pMin, pMax, Locator} 

en lugar de

{{p, {1, 1}}, Locator} 

pero se comporta completamente equivocado.

ACTUALIZACIÓN

Gracias a todos, este es mi solución final:

Manipulate[ 
distr1 = BinormalDistribution[p1, {1, 1}, \[Rho]1]; 
distr2 = BinormalDistribution[p2, {1, 1}, \[Rho]2]; 
Grid[ 
    { 
    {Graphics[{Locator[p1], Locator[p2]}, 
    PlotRange -> {{-5, 5}, {-5, 5}}]}, 
    {Plot3D[{PDF[distr1, {x, y}], PDF[distr2, {x, y}]}, {x, -5, 5}, {y, -5, 5}, PlotRange -> All]} 
    }], 
{{\[Rho]1, 0}, -0.9, 0.9}, {{\[Rho]2, 0}, -0.9, 0.9}, 
{{p1, {1, 1}}, Locator}, 
{{p2, {1, 1}}, Locator} 
] 

ACTUALIZACIÓN

Ahora el problema es que no puedo cambiar el tamaño y rotar el gráfico 3d más bajo. ¿Alguien sabe cómo arreglar eso? He vuelto a la solución con dos objetos Slider2D.

Answer 1

No estoy seguro de lo que está tratando de lograr. Hay una serie de problemas que veo, pero no sé a qué atenerme. Tal vez solo quieres una construcción simple Slider2D?

DynamicModule[{p = {1, 1}}, 
Column@{Slider2D[Dynamic[p], {{-3, -3}, {3, 3}}, 
    ImageSize -> {200, 200}], 
    Graphics[Line[{{0, 0}, Dynamic[p]}], 
    PlotRange -> {{-3, 3}, {-3, 3}}, ImageSize -> {200, 200}]}] 

---

Esta es una respuesta a la pregunta actualizada sobre 3D rotación gráfica.

Creo que LocatorPane como lo sugirió David es una buena forma de abordar esto. Acabo de poner en una función genérica ya que su ejemplo no se ejecutan en Mathematica 7.

DynamicModule[{pt = {{-1, 3}, {1, 1}}}, 
Column[{ 
    LocatorPane[Dynamic[pt], 
    Framed@Graphics[{}, PlotRange -> {{-5, 5}, {-5, 5}}]], 
    Dynamic@ 
    Plot3D[{x^2 pt[[1, 1]] + y^2 pt[[1, 2]], 
      -x^2 pt[[2, 1]] - y^2 pt[[2, 1]]}, 
     {x, -5, 5}, {y, -5, 5}] 
}] 
] 

Answer 2

Si examina el inputform encontrará que GraphicsGrid devuelve un objeto Graphics. Por lo tanto, el localizador realmente se mueve a lo largo de toda la imagen.

GraphicsGrid[{{Graphics[Circle[]]}, {Graphics[Disk[]]}}] // InputForm 

Si sólo cambia el GraphicsGrid a una cuadrícula, el localizador se limitará a la primera parte, pero el resultado todavía se ve un poco extraño. Su especificación PlotRange es un poco extraña; no parece corresponder a ningún formato especificado en el Centro de documentación. Tal vez quieras algo como lo siguiente.

Manipulate[ 
Grid[{ 
    {Graphics[Locator[p], Axes -> True, 
    PlotRange -> {{-3, 3}, {-3, 3}}]}, 
    {Graphics[Line[{{0, 0}, p}], Axes -> True, 
    PlotRange -> {{-3, 3}, {-3, 3}}]}}, 
    Frame -> All], 
{{p, {1, 1}}, Locator}] 

Answer 3

LocatorPane[] hace un buen trabajo de confinar el localizador a una región.

Esta es una variación del método utilizado por Mr. Wizard.

Column[{ LocatorPane[Dynamic[pt3], 
    Framed@Graphics[{}, ImageSize -> 150, PlotRange -> 3]], 
    Framed@Graphics[{Line[{{-1, 0}, Dynamic@pt3}]}, ImageSize -> {150, 150}, 
    PlotRange -> 3]}] 

habría dado por hecho que usted desea que el localizador para compartir el espacio con la línea que controla. De hecho, para ser "conectado" a la línea. Esto resulta ser aún más fácil de implementar.

Column[{LocatorPane[Dynamic[pt3],Framed@Graphics[{Line[{{-1, 0}, Dynamic@pt3}]}, 
ImageSize -> 150, PlotRange -> 3]]}]