MS Access envía un correo electrónico (no desde Outlook o el correo electrónico del usuario)

Question

Sé que esta pregunta se ha hecho varias veces en varios contextos, pero no he encontrado una respuesta clara. He implementado un correo electrónico para una aplicación de acceso que usa Outlook, pero me gustaría alejarme de esto. Uno de los propósitos del correo electrónico es enviar por correo electrónico a un usuario su contraseña si la olvidó. Pueden seleccionar su nombre de usuario para la pantalla de inicio de sesión, y si hacen clic en "contraseña olvidada" y se envía un correo electrónico que contiene su información de inicio de sesión (a la dirección de correo electrónico asociada con el nombre de usuario).

El problema con esto es que la función de correo electrónico como es envía un correo electrónico con Outlook desde la máquina del usuario. Por lo tanto, los usuarios podrían 'olvidar la contraseña' de otros nombres de usuario y ver su propia salida outbox (elementos enviados) para ver la información confidencial.

¿Hay alguna manera de enviar correos electrónicos como la función de correo de php, enviando correos desde el servidor? Me gustaría que los correos electrónicos se envíen desde la misma dirección de correo electrónico (por ejemplo, support@company.com), en lugar de desde la dirección de Outlook del usuario después de un aviso de seguridad. Si esto no es posible, estoy abierto a la idea de cualquier otra solución alternativa.

También agregaré que la instalación de cualquier software que tenga que instalarse en la máquina de cada usuario potencial no es factible.

¿Esto es posible?

Answer 1

Windows incluye un objeto de datos de colaboración denominado objetos o CDO. Este objeto le permite enviar correos electrónicos usando cualquier servidor SMTP asumiendo que se cumplan otros requisitos previos (firewall abierto, ISP no bloquea los puertos, la cuenta está configurada en el servidor SMTP, el servidor SMTP permite la retransmisión, etc.).

La mayoría de los ejemplos que he encontrado utilizan el enlace tardío, que es el preferido. En mi prueba en XP, parece que la referencia correcta de la biblioteca, si prefiere usar el enlace anticipado, es "Microsoft CDO para Windows 2000 Library".

Es importante saber que cada vez que envíe un correo electrónico deberá enviarlo a través de (o fuera de) algún tipo de servidor de correo electrónico. Esto significa que tendrá que autenticarse con ese servidor de correo electrónico y también significa que debe enviar el correo electrónico utilizando una dirección de correo electrónico "De" que existe en ese mismo servidor de correo electrónico.

Aquí hay un código que utiliza el enlace:

Const cdoSendUsingPickup = 1 
Const cdoSendUsingPort = 2 
Const cdoAnonymous = 0 
' Use basic (clear-text) authentication. 
Const cdoBasic = 1 
' Use NTLM authentication 
Const cdoNTLM = 2 'NTLM 

Public Sub SendEmail() 
    Dim imsg As Object 
    Dim iconf As Object 
    Dim flds As Object 
    Dim schema As String 

    Set imsg = CreateObject("CDO.Message") 
    Set iconf = CreateObject("CDO.Configuration") 
    Set flds = iconf.Fields 

    ' send one copy with SMTP server (with autentication) 
    schema = "http://schemas.microsoft.com/cdo/configuration/" 
    flds.Item(schema & "sendusing") = cdoSendUsingPort 
    flds.Item(schema & "smtpserver") = "mail.myserver.com" 
    flds.Item(schema & "smtpserverport") = 25 
    flds.Item(schema & "smtpauthenticate") = cdoBasic 
    flds.Item(schema & "sendusername") = "email@email.com" 
    flds.Item(schema & "sendpassword") = "password" 
    flds.Item(schema & "smtpusessl") = False 
    flds.Update 

    With imsg 
     .To = "email@email.com" 
     .From = "email@email.com" 
     .Subject = "Test Send" 
     .HTMLBody = "Test" 
     '.Sender = "Sender" 
     '.Organization = "My Company" 
     '.ReplyTo = "address@mycompany.com" 
     Set .Configuration = iconf 
     .Send 
    End With 

    Set iconf = Nothing 
    Set imsg = Nothing 
    Set flds = Nothing 
End Sub 

Answer 2

Esto funciona para mí en MS Access 2010/Windows 7

sMailServer = "myISPsmtp" 'Not just any old smtp 
sMailFromAddress = "me" 
sMailToAddress = "me" 

Set ObjMessage = CreateObject("CDO.Message") 
sToAddress = sMailToAddress 
sSubject = "Subject" 
sBody = "MailBody" 

ObjMessage.Subject = sSubject 
ObjMessage.From = sMailFromAddress 
ObjMessage.To = sToAddress 
'ObjMessage.cc = sCCAddress 
ObjMessage.TextBody = sBody 
'ObjMessage.AddAttachment sMailAttachment 
ObjMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
ObjMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = sMailServer 
ObjMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
ObjMessage.Configuration.Fields.Update 
ObjMessage.send 

Más información: http://msdn.microsoft.com/en-us/library/ms526318(v=exchg.10).aspx

Answer 3

No puedo añadir esto a los comentarios porque no tengo la reputación suficiente, así que por favor no me hacha.

"Parece que este método permite SPOOF de nada en mi servidor. Acabo de dar cuenta de que hay un método addAttachment. Podría que el trabajo con sólo una ruta relativa decir, una hoja de Excel?"

Funciona para mí (Access 2010, Exchange 2010):

.AddAttachment ("URL aquí")

https://msdn.microsoft.com/en-us/library/ms526453(v=exchg.10).aspx https://msdn.microsoft.com/en-us/library/ms526983(v=exchg.10).aspx

Answer 4

El siguiente código de trabajo MS-Access VBA s para smtp.office365.com.Indique smtpusessl = verdadero, pero NO especifique el puerto; de lo contrario, obtendrá el error 5.7.57.

Sub SMPTTest2() 
Set emailObj = CreateObject("CDO.Message") 

emailObj.From = "name@myaddress.com" 
emailObj.To = "name@youraddress.com" 
emailObj.Subject = "Test CDO" 
emailObj.TextBody = "Test CDO" 
'emailObj.AddAttachment "c:\windows\win.ini" 

Set emailConfig = emailObj.Configuration 


emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.office365.com" 
'Exclude the following line  
'emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 587 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = "name@myaddress.com" 
emailConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "mypassword" 
emailConfig.Fields.Update 

emailObj.Send 

If Err.Number = 0 Then MsgBox "Done" 
End Sub 

Answer 5

En mi empresa usé otra solución. Creé una biblioteca de clases C# con clases/objetos COM. Las clases COM se pueden implementar en su aplicación de Access y de esta manera puede usar todas las ventajas de C# (Mailing por ejemplo) y aún así usarlo (llamarlo) en Access.

La única desventaja es que debe registrar su Biblioteca de clases (DLL) en todas las computadoras que usan su aplicación de acceso. Lo he hecho con un simple script de power-shell que se ejecuta al inicio de la aplicación Access.

Un buen punto de partida para una biblioteca basada en COM está aquí: https://www.codeproject.com/Articles/7859/Building-COM-Objects-in-C

Si desea algo más de información al respecto a continuación, siempre estoy feliz de ayudarle.