Delphi XE - Las acciones de TRibbon siempre envían focus a MainForm

Question

Cuando coloco un control TRibbon en un formulario que no es el MainForm de la aplicación, las acciones de TRibbon (es decir, Cut, Paste) siempre devolverán el foco al MainForm después de la acción es ejecutado.

Esto ocurre incluso si el TForm que contiene el TRibbon no es un elemento secundario de MainForm.

Estoy usando Windows 7 de 64 bits, Embarcadero RAD Studio XE versión 15.0.3953.35171.

¿Estoy usando el control TRibbon incorrectamente, o es esto un problema con el TRibbon?

Answer 1

Esto es evidentemente por diseño. Código de la muestra fragmento de '' ribbonactnctrls.pas:

procedure TRibbonBaseButtonControl.Click; 
begin 
    inherited; 
    SetFocus(Application.MainForm.Handle); 
end; 

Como se puede ver que no hay condiciones controladas que ayudarían a evitar la llamada. También hay el mismo código en la selección de elementos del menú y en los controladores de pulsación de teclas.

Probablemente modificaría la fuente comentando las llamadas de enfoque, y trataré de ver si hay algún efecto secundario.

Como alternativa, puede restaurar el enfoque a su formulario después de que se cambie al formulario principal. Supongamos 'ActionList1' es el TActionList que contiene las acciones estándar en el formulario principal no :

type 
    TForm2 = class(TForm) 
    .. 
    procedure ActionList1Execute(Action: TBasicAction; var Handled: Boolean); 
    private 
    .. 

procedure TForm2.ActionList1Execute(Action: TBasicAction; var Handled: Boolean); 
begin 
    PostMessage(Handle, WM_SETFOCUS, WPARAM(True), 0); 
end; 

Este será sin embargo causar la forma principal a parpadear brevemente cada vez que se ejecuta una acción. Si no quieres eso, puedes cambiar el diseño para que el formulario principal sepa cuándo está recibiendo un enfoque no deseado y simular que no está enfocado.

En unidad1:

const 
    UM_CANCELIGNOREFOCUS = WM_USER + 7; 

type 
    TForm1 = class(TForm) 
    .. 
    private 
    FIgnoreFocus: Boolean; 
    procedure UMCancelIgnoreFocus(var Msg: TMessage); message UM_CANCELIGNOREFOCUS; 
    procedure WMNCActivate(var Msg: TWMNCActivate); message WM_NCACTIVATE; 
    public 
    property IgnoreFocus: Boolean write FIgnoreFocus; 
    end; 

... 
uses Unit2; 

procedure TForm1.WMNCActivate(var Msg: TWMNCActivate); 
begin 
    Msg.Result := 0; 
    if not (Msg.Active and FIgnoreFocus) then 
    inherited; 
end; 

procedure TForm1.UMCancelIgnoreFocus(var Msg: TMessage); 
begin 
    FIgnoreFocus := False; 
    TForm(Msg.WParam).SetFocus; 
end; 

en unit2:

uses 
    unit1; 

procedure TForm2.ActionList1Execute(Action: TBasicAction; var Handled: Boolean); 
begin 
    Form1.IgnoreFocus := True; 
    PostMessage(Form1.Handle, UM_CANCELIGNOREFOCUS, NativeInt(Self), 0); 
end; 

Sin embargo, esto no es suficiente si no se ha configurado 'MainFormOnTaskBar' en la fuente del proyecto, desde entonces, la forma principal no solo ganará foco, sino que será llevado al frente. En este caso, ambas formas podrían responder al cambio/activación de foco no deseado congelando sus z-órdenes. El código entonces convertido para unidad1:

const 
    UM_CANCELIGNOREFOCUS = WM_USER + 7; 

type 
    TForm1 = class(TForm) 
    .. 
    private 
    FIgnoreFocus: Boolean; 
    procedure UMCancelIgnoreFocus(var Msg: TMessage); message UM_CANCELIGNOREFOCUS; 
    procedure WMNCActivate(var Msg: TWMNCActivate); message WM_NCACTIVATE; 
    procedure WMWindowPosChanging(var Msg: TWMWindowPosChanging); 
     message WM_WINDOWPOSCHANGING; 
    public 
    property IgnoreFocus: Boolean read FIgnoreFocus write FIgnoreFocus; 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

uses Unit2; 

procedure TForm1.WMNCActivate(var Msg: TWMNCActivate); 
begin 
    Msg.Result := 0; 
    if not (Msg.Active and FIgnoreFocus) then 
    inherited; 
end; 

procedure TForm1.WMWindowPosChanging(var Msg: TWMWindowPosChanging); 
begin 
    inherited; 
    if FIgnoreFocus then 
    Msg.WindowPos.flags := Msg.WindowPos.flags or SWP_NOZORDER; 
end; 

procedure TForm1.UMCancelIgnoreFocus(var Msg: TMessage); 
begin 
    FIgnoreFocus := False; 
    TForm(Msg.WParam).SetFocus; 
end; 

y para unit2:

type 
    TForm2 = class(TForm) 
    .. 
    procedure ActionList1Execute(Action: TBasicAction; var Handled: Boolean); 
    private 
    procedure WMWindowPosChanging(var Msg: TWMWindowPosChanging); 
     message WM_WINDOWPOSCHANGING; 
    public 
    end; 

var 
    Form2: TForm2; 

implementation 

uses 
    unit1; 

{$R *.dfm} 

procedure TForm2.ActionList1Execute(Action: TBasicAction; var Handled: Boolean); 
begin 
    Form1.IgnoreFocus := True; 
    PostMessage(Form1.Handle, UM_CANCELIGNOREFOCUS, NativeInt(Self), 0); 
end; 

procedure TForm2.WMWindowPosChanging(var Msg: TWMWindowPosChanging); 
begin 
    inherited; 
    if Form1.IgnoreFocus then 
    Msg.WindowPos.flags := Msg.WindowPos.flags or SWP_NOZORDER; 
end;