¿Cómo leo los contenidos de un directorio en Perl?

Question

¿Cómo logro que Perl lea los contenidos de un directorio determinado en una matriz?

Backticks puede hacerlo, pero ¿hay algún método que use 'scandir' o un término similar?

Answer 1

opendir(D, "/path/to/directory") || die "Can't open directory: $!\n"; 
while (my $f = readdir(D)) { 
    print "\$f = $f\n"; 
} 
closedir(D); 

EDIT: Ah, lo siento, se perdió el "en una matriz" parte:

my $d = shift; 

opendir(D, "$d") || die "Can't open directory $d: $!\n"; 
my @list = readdir(D); 
closedir(D); 

foreach my $f (@list) { 
    print "\$f = $f\n"; 
} 

Edit2: La mayoría de las otras respuestas son válidas, pero quería hacer comentarios sobre this answer específicamente, en el cual esta solución se ofrece:

opendir(DIR, $somedir) || die "Can't open directory $somedir: $!"; 
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR); 
closedir DIR; 

en primer lugar, para documentar lo que está haciendo ya que el cartel no lo hizo: se pasa a la lista de regresar de readdir() a través de un grep() t solo devuelve aquellos valores que son archivos (a diferencia de directorios, dispositivos, canalizaciones con nombre, etc.) y que no comienzan con un punto (lo que hace que el nombre de la lista @dots sea engañoso, pero eso se debe al cambio que realizó al copiarlo más de la documentación readdir()). Como limita el contenido del directorio que devuelve, no creo que técnicamente sea una respuesta correcta a esta pregunta, pero ilustra una expresión común utilizada para filtrar nombres de archivo en Perl, y pensé que sería valioso documentar. Otro ejemplo se ve mucho es:

@list = grep !/^\.\.?$/, readdir(D); 

Este fragmento se lee todo el contenido de la manija directorio D excepto ''. y '..', ya que rara vez se desea utilizarlos en la lista.

Answer 2

Esto lo hará, en una línea (nótese el '*' comodín al final)

@files = </path/to/directory/*>; 
# To demonstrate: 
print join(", ", @files); 

Answer 3

He aquí un ejemplo de manera recursiva a través de una escritura de reserva froma estructura de directorios y archivos de copia escribí.

sub copy_directory { 
my ($source, $dest) = @_; 
my $start = time; 

# get the contents of the directory. 
opendir(D, $source); 
my @f = readdir(D); 
closedir(D); 

# recurse through the directory structure and copy files. 
foreach my $file (@f) { 
    # Setup the full path to the source and dest files. 
    my $filename = $source . "\\" . $file; 
    my $destfile = $dest . "\\" . $file; 

    # get the file info for the 2 files. 
    my $sourceInfo = stat($filename); 
    my $destInfo = stat($destfile); 

    # make sure the destinatin directory exists. 
    mkdir($dest, 0777); 

    if ($file eq '.' || $file eq '..') { 
    } elsif (-d $filename) { # if it's a directory then recurse into it. 
     #print "entering $filename\n"; 
     copy_directory($filename, $destfile); 
    } else { 
     # Only backup the file if it has been created/modified since the last backup 
     if((not -e $destfile) || ($sourceInfo->mtime > $destInfo->mtime)) { 
      #print $filename . " -> " . $destfile . "\n"; 
      copy($filename, $destfile) or print "Error copying $filename: $!\n"; 
     } 
    } 
} 

print "$source copied in " . (time - $start) . " seconds.\n";  
} 

Answer 4

IO::Dir es agradable y proporciona una interfaz de hash atado así.

Desde el perldoc:

use IO::Dir; 
$d = IO::Dir->new("."); 
if (defined $d) { 
    while (defined($_ = $d->read)) { something($_); } 
    $d->rewind; 
    while (defined($_ = $d->read)) { something_else($_); } 
    undef $d; 
} 

tie %dir, 'IO::Dir', "."; 
foreach (keys %dir) { 
    print $_, " " , $dir{$_}->size,"\n"; 
} 

Por lo que podría hacer algo como:

tie %dir, 'IO::Dir', $directory_name; 
my @dirs = keys %dir; 

Answer 5

Una solución rápida y sucia es utilizar glob

@files = glob ('/path/to/dir/*'); 

Answer 6

similar a la anterior, pero creo que la mejor versión (ligeramente modificada) de "perldoc -f readdir":

opendir(DIR, $somedir) || die "can't opendir $somedir: $!"; 
@dots = grep { (!/^\./) && -f "$somedir/$_" } readdir(DIR); 
closedir DIR; 

Answer 7

Usted podría utilizar DirHandle:

use DirHandle; 
$d = new DirHandle "."; 
if (defined $d) 
{ 
    while (defined($_ = $d->read)) { something($_); } 
    $d->rewind; 
    while (defined($_ = $d->read)) { something_else($_); } 
    undef $d; 
} 

DirHandle proporciona una alternativa, la interfaz más limpia a los opendir(), closedir(), readdir() y rewinddir() funciones.

Answer 8

de: http://perlmeme.org/faqs/file_io/directory_listing.html

#!/usr/bin/perl 
use strict; 
use warnings; 

my $directory = '/tmp'; 

opendir (DIR, $directory) or die $!; 

while (my $file = readdir(DIR)) { 
    next if ($file =~ m/^\./); 
    print "$file\n"; 
} 

El siguiente ejemplo (en base a un ejemplo de código de readdir perldoc f) se lleva todos los archivos (no directorios) que comienzan con un periodo desde el directorio abierto. Los nombres de archivo se encuentran en la matriz @dots.

#!/usr/bin/perl 

use strict; 
use warnings; 

my $dir = '/tmp'; 

opendir(DIR, $dir) or die $!; 

my @dots 
    = grep { 
     /^\./    # Begins with a period 
    && -f "$dir/$_" # and is a file 
} readdir(DIR); 

# Loop through the array printing out the filenames 
foreach my $file (@dots) { 
    print "$file\n"; 
} 

closedir(DIR); 
exit 0; 


closedir(DIR); 
exit 0;