¿Cómo se puede eliminar automáticamente el espacio en blanco al final en vim

Question

Estoy recibiendo errores de 'espacio en blanco al final' tratando de confirmar algunos archivos en git.

Quiero eliminar estos caracteres de espacios en blanco al final justo antes de guardar los archivos de Python.

¿Puedes configurar vim para hacer esto? ¿Si es así, cómo?

Answer 1

Encontré la respuesta here.

Agregando lo siguiente a mi archivo .vimrc hizo el truco.

autocmd BufWritePre *.py :%s/\s\+$//e 

Answer 2

También suele haber un número:

match Todo /\s\+$/ 

en mi archivo .vimrc, por lo que al final de la línea de espacio en blanco se hilighted.

Todo ser un resaltado de sintaxis group-name que se utiliza para palabras clave hilighting como TODO, FIXME o XXX. Tiene un color de fondo amarillento molesto feo, y me parece que es el mejor para ocultar cosas que no quiere en su código :-)

Answer 3

Así es como lo estoy haciendo. No puedo recordar dónde lo robé de tbh.

autocmd BufWritePre * :call <SID>StripWhite() 
fun! <SID>StripWhite() 
    %s/[ \t]\+$//ge 
    %s!^\(\+\)\t!\=StrRepeat("\t", 1 + strlen(submatch(1))/8)!ge 
endfun 

Answer 4

Compilación de lo anterior más el ahorro de posición del cursor:

fun! <SID>StripTrailingWhitespaces() 
    let l = line(".") 
    let c = col(".") 
    %s/\s\+$//e 
    call cursor(l, c) 
endfun 

autocmd FileType c,cpp,java,php,ruby,python autocmd BufWritePre <buffer> :call <SID>StripTrailingWhitespaces() 

Si desea aplicar esta en guardar a cualquier archivo, omiten el primer autocmd y utilizar un comodín *:

autocmd BufWritePre * :call <SID>StripTrailingWhitespaces() 

Answer 5

copiado y pegado de http://blog.kamil.dworakowski.name/2009/09/unobtrusive-highlighting-of-trailing.html (el enlace ya no funciona, pero el bit que necesita está abajo)

"Esto tiene la ventaja de no resaltar cada espacio que escriba al final de la línea, solo cuando abra un archivo o salga del modo de inserción. Es muy ordenado ".

highlight ExtraWhitespace ctermbg=red guibg=red 
au ColorScheme * highlight ExtraWhitespace guibg=red 
au BufEnter * match ExtraWhitespace /\s\+$/ 
au InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/ 
au InsertLeave * match ExtraWhiteSpace /\s\+$/ 

Answer 6

Aquí está una manera de filtrar por más de un tipo de archivo.

autocmd FileType c,cpp,python,ruby,java autocmd BufWritePre <buffer> :%s/\s\+$//e 

Answer 7

yo resalte existente espacios en blanco, y también tira espacios en blanco finales.

puedo configurar mi editor (vim) para mostrar espacios en blanco al final, p. ej.

con esta en la parte inferior de mi .vimrc:

highlight ExtraWhitespace ctermbg=red guibg=red 
match ExtraWhitespace /\s\+$/ 
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/ 
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/ 
autocmd InsertLeave * match ExtraWhitespace /\s\+$/ 
autocmd BufWinLeave * call clearmatches() 

y yo 'auto-tira' que a partir de archivos al guardar ellos, en mi caso * .rb para los archivos de rubí, de nuevo en mi ~ /.vimrc

function! TrimWhiteSpace() 
    %s/\s\+$//e 
endfunction 
autocmd BufWritePre  *.rb :call TrimWhiteSpace() 

Answer 8

Una solución que simplemente elimina los espacios en blanco del archivo no es aceptable en todas las circunstancias. Funcionará en un proyecto que ha tenido esta política desde el principio, por lo que no hay espacios en blanco que no se haya agregado a sí mismo en su próximo compromiso.

Suponga que desea simplemente no agregar nuevas instancias de espacios en blanco al final, sin afectar el espacio en blanco existente en líneas que no editó, para mantener su confirmación libre de cambios que son irrelevantes para su trabajo.

En ese caso, con git, se puede se puede utilizar un script como el siguiente:

#!/bin/sh 

set -e # bail on errors 

git stash save commit-cleanup 
git stash show -p | sed '/^\+/s/ *$//' | git apply 
git stash drop 

Es decir, que STASH los cambios, y luego filtrar todos los + líneas en el diff para eliminar su trazando un espacio en blanco a medida que volvemos a aplicar el cambio al directorio de trabajo. Si este conducto de comando es exitoso, dejamos el alijo.

Answer 9

Los otros enfoques aquí de alguna manera no funcionaron para mí en MacVim cuando se usan en el archivo .vimrc. Así que aquí hay uno que hace y destaca los espacios finales:

set encoding=utf-8 
set listchars=trail:· 
set list 

Answer 10

autocmd BufWritePre * :%s/\s\+$//<CR>:let @/=''<CR>

Answer 11

Para las personas que quieren ejecutarlo para tipos de archivo específicos (FileTypes no siempre son fiables):

autocmd BufWritePre *.c,*.cpp,*.cc,*.h,*.hpp,*.py,*.m,*.mm :%s/\s\+$//e 

O con vim7:

autocmd BufWritePre *.{c,cpp,cc,h,hpp,py,m,mm} :%s/\s\+$//e 

Answer 12

Si recorta los espacios en blanco, usted debe solo hágalo en archivos que ya estén limpios. "Cuando en Roma...". Esta es una buena etiqueta cuando se trabaja en bases de código donde los cambios falsos no son bienvenidos.

Esta función detecta los espacios en blanco al final y activa el recorte solo si ya estaba limpio.

El mérito de esta idea va a una joya de un comentario aquí: https://github.com/atom/whitespace/issues/10 (bug comentario billete de flujo más larga)

autocmd BufNewFile,BufRead *.test call KarlDetectWhitespace() 

fun! KarlDetectWhitespace() 
python << endpython 
import vim 
nr_unclean = 0 
for line in vim.current.buffer: 
    if line.rstrip() != line: 
     nr_unclean += 1 

print "Unclean Lines: %d" % nr_unclean 
print "Name: %s" % vim.current.buffer.name 
cmd = "autocmd BufWritePre <buffer> call KarlStripTrailingWhitespace()" 
if nr_unclean == 0: 
    print "Enabling Whitespace Trimming on Save" 
    vim.command(cmd) 
else: 
    print "Whitespace Trimming Disabled" 
endpython 
endfun 

fun! KarlStripTrailingWhitespace() 
    let l = line(".") 
    let c = col(".") 
    %s/\s\+$//e 
    call cursor(l, c) 
endfun 

Answer 13

vi esta solución en un comentario en VIM Wikia - Remove unwanted spaces

Realmente le gustó. Agrega un . en los espacios en blanco no deseados.

poner esto en su .vimrc

" Removes trailing spaces 
function TrimWhiteSpace() 
    %s/\s*$// 
    '' 
endfunction 

set list listchars=trail:.,extends:> 
autocmd FileWritePre * call TrimWhiteSpace() 
autocmd FileAppendPre * call TrimWhiteSpace() 
autocmd FilterWritePre * call TrimWhiteSpace() 
autocmd BufWritePre * call TrimWhiteSpace()