¿Por qué esta declaración del mapa en Perl no se compila?

Question

Esta falla:

my @a = ("a", "b", "c", "d", "e"); 
my %h = map { "prefix-$_" => 1 } @a; 

con este error:

Not enough arguments for map at foo.pl line 4, near "} @a" 

pero esto funciona:

my @a = ("a", "b", "c", "d", "e"); 
my %h = map { "prefix-" . $_ => 1 } @a; 

por qué?

Answer 1

Porque Perl está adivinando una EXPR (una referencia de hash, por ejemplo) en lugar de un BLOQUE. Esto debería funcionar (nótese el símbolo '+'):

my @a = ("a", "b", "c", "d", "e"); 
my %h = map { +"prefix-$_" => 1 } @a; 

Ver http://perldoc.perl.org/functions/map.html.

Answer 2

De perldoc -f map:

  "{" starts both hash references and blocks, so "map { ..." 
      could be either the start of map BLOCK LIST or map EXPR, LIST. 
      Because perl doesn’t look ahead for the closing "}" it has to 
      take a guess at which its dealing with based what it finds just 
      after the "{". Usually it gets it right, but if it doesn’t it 
      won’t realize something is wrong until it gets to the "}" and 
      encounters the missing (or unexpected) comma. The syntax error 
      will be reported close to the "}" but you’ll need to change 
      something near the "{" such as using a unary "+" to give perl 
      some help: 

      %hash = map { "\L$_", 1 } @array # perl guesses EXPR. wrong 
      %hash = map { +"\L$_", 1 } @array # perl guesses BLOCK. right 
      %hash = map { ("\L$_", 1) } @array # this also works 
      %hash = map { lc($_), 1 } @array # as does this. 
      %hash = map +(lc($_), 1), @array # this is EXPR and works! 
      %hash = map (lc($_), 1), @array # evaluates to (1, @array) 

      or to force an anon hash constructor use "+{" 

      @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end 

      and you get list of anonymous hashes each with only 1 entry. 

Answer 3

prefiero escribir que a medida que

my %h = map { ("prefix-$_" => 1) } @a; 

para mostrar la intención, que yo estoy devolviendo una lista de 2 elementos.

Answer 4

Además, la otra manera de hacer lo que estás haciendo, inicializar el hash, puede hacerlo de esta manera:

my @a = qw(a b c d e); 
my %h; 
@h{@a} =(); 

que va a crear entradas undef para cada una de las cinco teclas. Si quieres darles todos los valores verdaderos, haz esto.

@h{@a} = (1) x @a; 

También puede hacerlo explícitamente con un bucle;

@h{$_} = 1 for @a; 

Answer 5

creo que

map { ; "prefix-$_" => 1 } @a; 

es más idiomática, por lo que se especifica que se trata de un bloque de instrucciones y no un ref hash. Estás empezando con una declaración nula.