¿Cómo crear un caso de TEqualityComparer en caso de TDictionary?

Question

tengo un caso utilizando TDictionary:

var D: TDictionary<string, integer>; 
begin 
    D := TDictionary<string, integer>.Create(TCustomEqualityComparer.Create()); 
    try 
    D.Add('One', 1); 
    D.Add('Two', 2); 
    D.Add('Three', 3); 

    showmessage(inttostr(D.Items['One'])); 
    showmessage(inttostr(D.Items['TWO'])); 
    finally 
    D.Free; 
    end; 
end; 

Clase TCustomEqualityComparer se copia de Generics Defaults TEqualityComparer (Delphi) con modificaciones menores en el método GetHashCode:

TCustomEqualityComparer = class(TEqualityComparer<string>) 
public 
    function Equals(const Left, Right: string): Boolean; override; 
    function GetHashCode(const Value: string): Integer; override; 
end; 

function TCustomEqualityComparer.Equals(const Left, Right: string): Boolean; 
begin 
    Result := SameText(Left, Right); 
end; 

function TCustomEqualityComparer.GetHashCode(const Value: string): Integer; 
begin 
    Result := BobJenkinsHash(Value[1], Length(Value) * SizeOf(Value[1]), 0); 
end; 

lo esperado El TCustomEqualityComparer capaz de realizar la coincidencia entre mayúsculas y minúsculas para el valores clave Por ejemplo:

D.Items['TWO'] 

Sin embargo, aparece la excepción "Objeto no encontrado". Estoy usando Delphi 2010 versión 14.0.3513.24210.

¿Alguien sabe cómo funciona mi código?

Answer 1

Gracias. He cambiado TCustomEqualityComparer.GetHashCode y funciona como usted ha dicho:

function TCustomEqualityComparer.Equals(const Left, Right: string): Boolean; 
begin 
    Result := SameText(Left, Right); 
end; 

function TCustomEqualityComparer.GetHashCode(const Value: string): Integer; 
var s: string; 
begin 
    s := UpperCase(Value); 
    Result := BobJenkinsHash(s[1], Length(s) * SizeOf(s[1]), 0); 
end; 

Answer 2

El HashCode tiene que ser el mismo para todos los valores que devuelven Equals = true. Intenta hacer que el valor sea mayúscula en GetHashCode antes de enviarlo a tu HashFunction.

Answer 3

uses System.Generics.Collections, System.Generics.Defaults; 

var 
    D: TDictionary<string, Integer>; 
begin 
    D := TDictionary<string, Integer>.Create(TIStringComparer.Ordinal); // ‹- this is the trick 
    try 
    D.Add('One', 1); 
    . 
    . 
    finally 
    D.Free; 
    end; 
end;