¿xslt tiene la función de división()?

Question

¿Cómo se divide una cadena basada en algún separador?

Dada una cadena Topic1,Topic2,Topic3, quiero dividir la cadena basada en , para generar:

Topic1 Topic2 Topic3 

Answer 1

En XSLT 1.0 tiene que crear una plantilla recursiva. Esta hoja de estilo:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="text/text()" name="tokenize"> 
     <xsl:param name="text" select="."/> 
     <xsl:param name="separator" select="','"/> 
     <xsl:choose> 
      <xsl:when test="not(contains($text, $separator))"> 
       <item> 
        <xsl:value-of select="normalize-space($text)"/> 
       </item> 
      </xsl:when> 
      <xsl:otherwise> 
       <item> 
        <xsl:value-of select="normalize-space(substring-before($text, $separator))"/> 
       </item> 
       <xsl:call-template name="tokenize"> 
        <xsl:with-param name="text" select="substring-after($text, $separator)"/> 
       </xsl:call-template> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet> 

de entrada:

<root> 
<text>Item1, Item2, Item3</text> 
</root> 

Salida:

<root> 
    <text> 
     <item>Item1</item> 
     <item>Item2</item> 
     <item>Item3</item> 
    </text> 
</root> 

En XSLT 2.0 que tiene la función de tokenize() núcleo. Por lo tanto, esta hoja de estilo:

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="text/text()" name="tokenize"> 
     <xsl:param name="separator" select="','"/> 
     <xsl:for-each select="tokenize(.,$separator)"> 
       <item> 
        <xsl:value-of select="normalize-space(.)"/> 
       </item> 
     </xsl:for-each> 
    </xsl:template> 
</xsl:stylesheet> 

Resultado:

<root> 
    <text> 
     <item>Item1</item> 
     <item>Item2</item> 
     <item>Item3</item> 
    </text> 
</root> 

Answer 2

No hay función split, pero se puede utilizar una plantilla recursiva con substring-before y substring-after para escribir el suyo propio.

Ver artículo this para más detalles.

Answer 3

Uso fn:tokenize

Answer 4

Gracias user357812. Utilizo su agradable plantilla con poco de personalización para que sea genérica:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <!-- Main template --> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()" mode="tokenize-children" /> 
     </xsl:copy> 
    </xsl:template> 

    <!-- Split child nodes --> 
    <xsl:template match="*" mode="tokenize-children"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*" /> 
      <xsl:apply-templates select="*" mode="tokenize" /> 
     </xsl:copy> 
    </xsl:template> 

    <!-- Tokenize text node of child nodes --> 
    <xsl:template match="*/text()" name="tokenize" mode="tokenize"> 
     <xsl:param name="text" select="."/> 
     <xsl:param name="separator" select="','"/> 
     <xsl:variable name="item" select="name(..)" /> 
     <xsl:choose> 
      <xsl:when test="not(contains($text, $separator))"> 
       <xsl:element name="{$item}"> 
        <xsl:value-of select="normalize-space($text)"/> 
       </xsl:element> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:element name="{$item}"> 
        <xsl:value-of select="normalize-space(substring-before($text, $separator))"/> 
       </xsl:element> 
       <xsl:call-template name="tokenize"> 
        <xsl:with-param name="text" select="substring-after($text, $separator)"/> 
       </xsl:call-template> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 5

Dependiendo de qué procesador XSL que está utilizando, es posible que tenga acceso a la función de extensión str:tokenize().

Para dividir Topic1,Topic2,Topic3 en , do;

<xsl:copy-of select="str:tokenize('Topic1,Topic2,Topic3', ',')"/> 

que dará el resultado;

<token>Topic1</token> 
<token>Topic2</token> 
<token>Topic3</token> 

Answer 6

XSLT 1.0
necesitaba una ligera variante en comparación con otras respuestas que se dan aquí.

de entrada:

1, 2, 3

Ouput:

1, 2 y 3

de entrada:

salida

Si el delimitador es el espacio en lugar de comas, todavía funcionaría.

de entrada:

Ouput:

1, 2 y 3

Acabo de crear una plantilla ligeramente modificada.

<xsl:template name="tokenizeString"> 
<xsl:param name="list"/> 
<xsl:param name="delimiter"/> 
<xsl:choose> 
    <xsl:when test="contains($list, $delimiter)">  
     <xsl:variable name="listLength" select="string-length($list)" /> 
     <xsl:variable name="listLengthWithoutDelimiters" select="string-length(translate($list, $delimiter,''))" /> 
     <xsl:variable name="noOfDelimiters" select="($listLength - $listLengthWithoutDelimiters)" /> 

     <xsl:value-of select="substring-before($list,$delimiter)"/> 
     <xsl:if test="$noOfDelimiters > 1">, </xsl:if> 
     <xsl:if test="$noOfDelimiters = 1"> and </xsl:if> 
     <xsl:call-template name="tokenizeString"> 
      <xsl:with-param name="list" select="substring-after($list,$delimiter)"/> 
      <xsl:with-param name="delimiter" select="$delimiter"/> 
     </xsl:call-template> 
    </xsl:when> 
    <xsl:otherwise> 
     <xsl:choose> 
      <xsl:when test="$list = ''"> 
       <xsl:text/> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:value-of select="$list"/> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:otherwise> 
</xsl:choose> 

La plantilla puede ser llamado como a continuación cuando el delimitador es coma

<xsl:call-template name="tokenizeString"> 
    <xsl:with-param name="list">1, 2, 3</xsl:with-param> 
    <xsl:with-param name="delimiter"> 
     <xsl:value-of select="','" /> 
    </xsl:with-param> 
</xsl:call-template> 

La plantilla puede ser llamado como a continuación cuando el delimitador es espacio

<xsl:call-template name="tokenizeString"> 
    <xsl:with-param name="list">1 2 3</xsl:with-param> 
    <xsl:with-param name="delimiter"> 
     <xsl:value-of select="' '" /> 
    </xsl:with-param> 
</xsl:call-template>