¿Cómo formateo la hora en [h]: formato mm excel usando la función de formateo() en VBA

Question

¿Es posible formatear la hora en formato [h]: mm usando VBA?

[h]: mm formato en Excel mostraría 25 horas como 25:00, 125 horas como 125: 00

He intentado varias cosas tales como:

format(datetime, "[h]:mm") 
format(datetime, "H:mm") 
format(datetime, "hh:mm") 

Ninguno de estos tener el efecto deseado También he echado un vistazo a través de la ayuda de MS y no encuentro nada útil.

Answer 1

utilizar la función TEXTO hoja de trabajo a través del objeto de aplicación, así como:

x = Application.Text(.294,"[h]:mm") 

Answer 2

no

con la función de formato, pero se puede usar Range(MyData).NumberFormat = "[h]:mm"

Answer 3

Parece que la función de VBA Format no tiene forma integrada de hacer esto. (Ojos que se mueven.)

Esta función casera hará el truco:

Function HoursAndMinutes(datetime As Date) As String 
    Dim hours As Integer 
    Dim minutes As Integer 
    hours = Int(datetime) * 24 + Hour(datetime) ' the unit of Date type is 1 day 
    minutes = Round((datetime * 24 - hours) * 60) 
    HoursAndMinutes = hours & ":" & Format(minutes, "00") 
End Function 

Uso:

Dim datetime As Date 
    datetime = TimeSerial(125, 9, 0) ' 125 hours and 9 minutes 
    Debug.Print HoursAndMinutes(datetime) ' 125:09 

Answer 4

JFC se me adelantó, pero esto es lo que se me ocurrió de todos modos. ..

Sub Test() 
    Debug.Print FormatHM(24/24)  '24:00 
    Debug.Print FormatHM(25/24)  '25:00 
    Debug.Print FormatHM(48/24)  '48:00 
    Debug.Print FormatHM(48.6/24) '48:36 
End Sub 

Function FormatHM(v As Double) As String 
    FormatHM = Format(Application.Floor(v * 24, 1), "00") & _ 
       ":" & Format((v * 1440) Mod 60, "00") 

End Function