cadena Convert "abc" a $ picadillo -> {a} -> {b} -> {c} en Perl

Question

He anidados hash árbitros dinámicos como esto:

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } }; 

Quiero configurar el valor de c a 'algo' al permitir que el usuario ingrese "abc algo".

ahora conseguir el valor podría hacerse así:

my $keys = 'a.b.c'; 
my $v='something'; 
my $h = $hash; 
foreach my $k(split /\./, $keys) { 
    $h = $h->{$k}; 
} 
print $h; # "value" 

Pero ¿cómo iba a establecer el valor de clave c-$v modo que

print Dumper $hash; 

podría reflejar el cambio ? $h no es una referencia al final del ciclo foreach, por lo que cambiar eso no reflejará el cambio en $hash. ¿Alguna pista sobre cómo resolver los nudos en mi cabeza?

Answer 1

Algo como esto:

my $h = $hash; 
my @split_key = split /\./, $keys; 
my $last_key = pop @split_key; 
foreach my $k (@split_key) { 
    $h = $h->{$k}; 
} 
$h->{$last_key} = $v; 

Answer 2

use strictures; 
use Data::Diver qw(DiveVal); 

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } }, 
    'a.b.c', 
    'something', 
); 

DiveVal($hash, split /[.]/, $path) = $value; 
# { a => { b => { c => 'something' } } } 

Answer 3

estallar hacia fuera la última tecla es para los flojos! ;)

sub dive :lvalue { 
    my $r = \shift; 
    $r = \(($$r)->{$_}) for @_; 
    return $$r; 
} 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

dive($data, split /\./, $key) = $val; 

una versión más potente (y por lo tanto ligeramente más difícil de usar) de esta función es proporcionada por Data::Diver.

use Data::Diver qw(DiveVal); 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

DiveVal($data //= {}, map \$_, split /\./, $key) = $val; 

(el uso de daxim es ligeramente fuera.)