¿Cómo puedo serializar un cierre en Perl?

Question

creo que esto se le puede pedir con un ejemplo:

use strict; 
use warnings; 
use 5.010; 
use Storable qw(nstore retrieve); 

local $Storable::Deparse = 1; 
local $Storable::Eval = 1; 

sub sub_generator { 
    my ($x) = @_; 

    return sub { 
     my ($y) = @_; 
     return $x + $y; 
    }; 
} 

my $sub = sub_generator(1000); 
say $sub->(1); # gives 1001 
nstore($sub, "/tmp/sub.store"); 
$sub = retrieve("/tmp/sub.store"); 
say $sub->(1); # gives 1 

Cuando yo tiro /tmp/sub.store veo:

$VAR1 = sub { 
      package Storable; 
      use warnings; 
      use strict 'refs'; 
      my($y) = @_; 
      return $x + $y; 
     } 

Pero $x Nunca se define en esta sub. Esperaría que el submarino generado por sub_generator tenga $x reemplazado por su valor real en la generación. ¿Cómo debería resolver esto?

Tenga en cuenta que esta pregunta se relaciona con esto one.

Answer 1

Desafortunadamente no creo que Storable funcione con cierres. Sin embargo, hay otros módulos de CPAN que serializarán un cierre. Por ej. Data::Dump::Streamer

use 5.012; 
use warnings; 
use Data::Dump::Streamer; 

sub sub_generator { 
    my ($x) = @_; 

    return sub { 
     my ($y) = @_; 
     return $x + $y; 
    }; 
} 

my $sub = sub_generator(1000); 
say $sub->(1); # gives 1001 

my $serialised = Dump($sub)->Out; 
my $copy = do { 
    my $CODE1 = undef; 
    eval $serialised; 
    $CODE1; 
}; 

say $copy->(2); # gives 1002 
say $sub->(1); # still gives 1001 

Esto es lo que el código serializado se ve como cuando se imprime aquí, say Dump $sub;:

my ($x); 
$x = 1000; 
$CODE1 = sub { 
      use warnings; 
      use strict 'refs'; 
      BEGIN { 
      $^H{'feature_unicode'} = q(1); 
      $^H{'feature_say'} = q(1); 
      $^H{'feature_state'} = q(1); 
      $^H{'feature_switch'} = q(1); 
      } 
      my($y) = @_; 
      return $x + $y; 
     }; 

actualización

Ver este hilo Storable and Closures en el Perl5 porteadores lista de correo. Confirma lo que pensaba sobre Storable y cierres.

/I3az/