Copiando valores de un hash a otro en perl

Question

Tengo dos hashes, uno grande y uno pequeño. Todas las teclas hash más pequeñas aparecen en el hash más grande, pero los valores son diferentes. Quiero copiar los valores del hash más grande al hash más pequeño.

Ejem:

# I have two hashes like so 
%big_hash = (A => '1', B => '2', C => '3', D => '4', E => '5'); 
%small_hash = (A => '0', B => '0', C => '0'); 
# I want small_hash to get the values of big_hash like this 
%small_hash = (A => '1', B => '2', C => '3'); 

Una respuesta obvia sería colocar a través de las teclas de la pequeña almohadilla, y copiar los valores como esto

foreach $key (keys %small_hash) { $small_hash{$key} = $big_hash{$key}; } 

¿Hay un camino más corto para hacer esto ?

Answer 1

@small_hash{ keys %small_hash } = @big_hash{ keys %small_hash }; 

Answer 2

use strict; 
my %source = (a => 1, b => 2, c => 3); 
my %target = (a => -1, x => 7, y => 9); 

# Use a hash slice for the copy operation. 
# Note this will clobber existing values. 
# Which is probably what you intend here. 
@target{ keys %source } = values %source; 

for (sort keys %target) { 
    print $_, "\t", $target{ $_ }, "\n"; 
} 

Answer 3

Aquí está una manera que podría hacerlo:

%small = map { $_, $big{$_} } keys %small; 

Altho que es bastante similar a la de bucle.

$small{$_} = $big{$_} for keys %small; 

---

mapproof para aquellos que necesitan una:

my %big = (A => '1', B => '2', C => '3', D => '4', E => '5'); 
my %small = (A => '0', B => '0', C => '0'); 

%small = map { $_, $big{$_} } keys %small; 

print join ', ', %small; 

Salida:

A, 1, C, 3, B, 2