se pida la contraseña en la línea de comandos de Haskell

Question

El siguiente programa Haskell le pide al usuario una contraseña en el terminal y continúa si ha entrado en la correcta:

main = do 
    putStrLn "Password:" 
    password <- getLine 

    case hash password `member` database of 
     False -> putStrLn "Unauthorized use!" 
     True -> do 
       ... 

Desafortunadamente, aparecerá la contraseña en el pantalla a medida que el usuario la escribe, lo cual quiero evitar.

¿Cómo puedo leer una secuencia de caracteres que los usuarios escriben sin que aparezcan en la pantalla? ¿Cuál es el equivalente de getLine para este propósito?

Estoy en MacOS X, pero me gustaría que esto funcione en Windows y Linux, también.

Answer 1

pruebe el siguiente:

module Main 
where 

import System.IO 
import Control.Exception 

main :: IO() 
main = getPassword >>= putStrLn . ("Entered: " ++) 

getPassword :: IO String 
getPassword = do 
    putStr "Password: " 
    hFlush stdout 
    pass <- withEcho False getLine 
    putChar '\n' 
    return pass 

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = do 
    old <- hGetEcho stdin 
    bracket_ (hSetEcho stdin echo) (hSetEcho stdin old) action 

Answer 2

Es posible desactivar el eco en el terminal con the System.Posix.Terminal module. Sin embargo, esto requiere soporte POSIX, por lo que puede no funcionar en Windows (no lo compruebe).

import System.Posix.Terminal 
import System.Posix.IO (stdInput) 

getPassword :: IO String 
getPassword = do 
    tc <- getTerminalAttributes stdInput 
    setTerminalAttributes stdInput (withoutMode tc EnableEcho) Immediately 
    password <- getLine 
    setTerminalAttributes stdInput tc Immediately 
    return password 

main = do 
    putStrLn "Password:" 
    password <- getPassword 
    putStrLn "Name:" 
    name <- getLine 
    putStrLn $ "Your password is " ++ password ++ " and your name is " ++ name 

Tenga en cuenta que la entrada estándar es la línea de búfer, por lo que si se utiliza en lugar de putStr "Password:"putStrLn, es necesario vaciar el búfer en primer lugar, de lo contrario el indicador se inhibirá también.

Answer 3

Hay una getPassword en System.Console.Haskeline. Probablemente sea un exceso para su caso, pero a alguien le puede resultar útil.

Un ejemplo:

> runInputT defaultSettings $ do {p <- getPassword (Just '*') "pass:"; outputStrLn $ fromJust p} 
pass:*** 
asd 

Answer 4

Como ya he comentado anteriormente, le sugiero que utilice haskeline, que es una biblioteca rápida completa. Lo he usado felizmente para LambdaCalculator sin quejas.

Answer 5

withEcho se puede escribir con un poco menos ruido:

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = 
    bracket (hGetEcho stdin) 
      (hSetEcho stdin) 
      (const $ hSetEcho stdin echo >> action)