¿Cómo puedo determinar si se implementa un método abstracto?

Question

Estoy usando una gran biblioteca de terceros de Delphi sin código fuente, esta biblioteca tiene varias clases con métodos abstractos. Necesito determinar cuándo un método abtract es implementado por una clase Descendant en tiempo de ejecución para evitar el EAbstractError: Abstract Error y muestra un mensaje personalizado para el usuario o usa otra clase en su lugar.

por ejemplo en este código Quiero verificar en tiempo de ejecución si se implementa MyAbstractMethod.

type 
    TMyBaseClass = class 
    public 
    procedure MyAbstractMethod; virtual; abstract; 
    end; 

    TDescendantBase = class(TMyBaseClass) 
    public 
    end; 

    TChild = class(TDescendantBase) 
    public 
    procedure MyAbstractMethod; override; 
    end; 

    TChild2 = class(TDescendantBase) 
    end; 

¿Cómo puedo determinar si un método abstracto se implementa en una clase descendiente en tiempo de ejecución?

Answer 1

puede utilizar la función Rtti, GetDeclaredMethods obtener una lista de todos los métodos que se declaran en el tipo reflejado (actual). Entonces puede verificar si el método está presente en la lista devuelta por esta función.

function MethodIsImplemented(const AClass:TClass;MethodName : string): Boolean; 
var 
    m : TRttiMethod; 
begin 
    Result := False; 
    for m in TRttiContext.Create.GetType(AClass.ClassInfo).GetDeclaredMethods do 
    begin 
    Result := CompareText(m.Name, MethodName)=0; 
    if Result then 
    break; 
    end; 
end; 

o se puede comparar la propiedad Parent.Name del TRttiMethod y comprobar si partido con el nombre de la clase actual.

function MethodIsImplemented(const AClass:TClass;MethodName : string): Boolean; 
var 
    m : TRttiMethod; 
begin 
    Result := False; 
    m:=TRttiContext.Create.GetType(AClass.ClassInfo).GetMethod(MethodName); 
    if m<>nil then 
    Result:=CompareText(AClass.ClassName,m.Parent.Name)=0; 
end; 

Answer 2

vistazo a la implementación del método TStream.Seek() en el código fuente VCL. Lleva a cabo un tipo similar de cheque descuido de descendiente como lo que está buscando, y no implica búsquedas TRttiContext para hacerlo, simplemente un bucle simple a través de sus entradas vtable padre/hijo.

Answer 3

function ImplementsAbstractMethod(AObj: TMyBaseClass): Boolean; 
type 
    TAbstractMethod = procedure of object; 
var 
    BaseClass: TClass; 
    BaseImpl, Impl: TAbstractMethod; 
begin 
    BaseClass := TMyBaseClass; 
    BaseImpl := TMyBaseClass(@BaseClass).MyAbstractMethod; 
    Impl := AObj.MyAbstractMethod; 
    Result := TMethod(Impl).Code <> TMethod(BaseImpl).Code; 
end;