¿Puedes anular un constructor de clase y usar heredado?

Question

Cuando define un constructor de clase en una clase base (es decir, para establecer una variable de clase estática), ¿es posible anular este constructor de clase en una clase derivada y llamar al constructor desde su padre jerárquico con heredado?

Ejemplo:

TBaseclass = class(TObject) 
public 
    class constructor ClassCreate; virtual; 
end; 

TOtherClass = class(TBaseClass) 
public 
    class constructor ClassCreate; override; 
end; 

**implementation** 

class constructor TBaseClass.ClassCreate; 
begin 
    //do some baseclass stuff 
end; 

class constructor TotherClass.ClassCreate; 
begin 
    inherited; 
    //do some other stuff 
end; 

Answer 1

No hay ninguna razón para class constructors a ser virtual ya que no pueden ser invocados polimórfica. No puedes llamarlos directamente; el compilador les inserta llamadas automáticamente en función de qué clases se usan en un programa. Los métodos virtuales son para el polimorfismo en tiempo de ejecución, pero dado que el compilador sabe exactamente qué constructores de clase está invocando en tiempo de compilación, no hay necesidad de despacho dinámico en constructores de clase o destructores.

No se requieren métodos virtuales para herencia, sin embargo, no debería haber ningún problema al usar inherited en un constructor de clase o destructor de clase. Como señala David's answer, el compilador ignora las llamadas a inherited porque generalmente no es prudente inicializar una clase varias veces, que es lo que haría si realmente lograra llamar al constructor de clases heredado. Si hay algo que necesita suceder dos veces, deberá encontrar una forma diferente de hacerlo realidad.

Answer 2

Para empezar, ya que constructores de clase no pueden ser virtuales (que no tiene sentido para ellos ser virtual), tiene que quitar los virtual y override palabras clave para que su compilación de código.

Los constructores de clases se suelen utilizar para inicializar los vars de clase. Por lo general, los vars de clase deben inicializarse una vez y solo una vez. Si puede llamar al inherited de la manera que sugiere en la pregunta, entonces se llamaría al TBaseClass.ClassCreate varias veces cuando, de hecho, debe llamarse exactamente una vez.

Si bien puede escribir inherited en un constructor de clase y el código se compilará, el compilador simplemente lo ignorará.

program ClassConstructors; 

{$APPTYPE CONSOLE} 

uses 
    SysUtils; 

var 
    Count: Integer; 

type 
    TBaseclass = class 
    public 
    class constructor ClassCreate; 
    end; 

    TOtherClass = class(TBaseClass) 
    public 
    class constructor ClassCreate; 
    end; 

class constructor TBaseClass.ClassCreate; 
begin 
    inc(Count); 
end; 

class constructor TotherClass.ClassCreate; 
begin 
    inherited; 
end; 

begin 
    TBaseClass.Create.Free; 
    TOtherClass.Create.Free; 
    Writeln(Count);//outputs 1 
    Readln; 
end. 

Tenga en cuenta que, por supuesto, ambos constructores de clase se ejecutan.