búsqueda inversa en un mapa

Question

Tengo que extraer una clave de un mapa utilizando un valor. ¿Hay alguna manera de hacer esto aparte de implementar la búsqueda inversa?

Answer 1

Trate

(some #(if (= (val %) your-val) (key %)) your-map) 

Answer 2

Puede invertir un mapa muy fácilmente con una función de 2 líneas:

(defn reverse-map [m] 
    (into {} (map (fn [[a b]] [b a]) m))) 

(def a {:a 1 :b 2 :c 3}) 

(reverse-map a) 
=> {1 :a, 3 :c, 2 :b} 

((reverse-map a) 1) 
=> :a 

Answer 3

Otra:

(defn reverse-map [m]                               
    (apply hash-map (mapcat reverse m))) 

(defn reverse-lookup [m k]                              
    (ffirst (filter (comp #{k} second) m))) 

Answer 4

Creo que map-invert es el derecho forma de hacer esto.

From the docs:

;; Despite being in clojure.set, this has nothing to do with sets. 

user=> (map-invert {:a 1, :b 2}) 
{2 :b, 1 :a} 

;; If there are duplicate keys, one is chosen: 

user=> (map-invert {:a 1, :b 1}) 
{1 :b} 

;; I suspect it'd be unwise to depend on which key survives the clash. 

Answer 5

Si está utilizando ClojureScript o necesita una alternativa más :)

(zipmap (vals m) (keys m))

Answer 6

si desea guardar las llaves, es mejor simplemente invertir el mapa , pero recoge las llaves antiguas en un conjunto/lista, etc. ...

(defn map-inverse [m] 
    (reduce (fn [m' [k v]] (update m' v clojure.set/union #{k})) {} m)) 

(defn map-inverse [m] 
    (reduce (fn [m' [k v]] (update m' v conj k)) {} m))