¿Cómo puedo leer el contenido de un archivo en una lista en Lisp?

Question

Quiero leer el contenido de un archivo en una lista. Algunos de mis intentos han sido hasta ahora -

(defun get-file (filename) 
    (let ((x (open filename))) 
    (when x 
     (loop for line = (read-line x nil) 
    while line do (list line))) 
    (close x))) 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) (contents (list nil))) 
    (when x 
     (loop for line = (read-line x nil) 
    while line do (cons contents line))) 
    (close x) contents)) 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) (contents nil)) 
    (when x 
     (loop for line = (read-line x nil) 
    while line do (append contents line))) 
    (close x) contents)) 

Ninguno de ellos funcionó. ¿Alguien puede decirme una manera? O mejor aún: ¿cómo poner todos los contenidos en una matriz?

Answer 1

¿Qué tal

(defun get-file (filename) 
    (with-open-file (stream filename) 
    (loop for line = (read-line stream nil) 
      while line 
      collect line))) 

Answer 2

¿Dónde están los problemas?

(defun get-file (filename) 
    (let ((x (open filename))) 
    (when x 
     (loop for line = (read-line x nil) 
      while line 
      do (list line))) ; <-- you are not collecting, just doing 
    (close x)))     ; <- the function returns the value of CLOSE 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) 
     (contents (list nil))) 
    (when x 
     (loop for line = (read-line x nil) 
      while line 
      do (cons contents line))) ; <-- again, the cons goes nowhere 
    (close x) contents))    ; <-- CONTENTS has never been changed 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) 
     (contents nil)) 
    (when x 
     (loop for line = (read-line x nil) 
      while line 
      do (append contents line))) ; <- again the result goes nowhere 
    (close x) contents))     ; <-- CONTENTS has never been changed 

DO simplemente ejecutará algo para los efectos secundarios.

COLLECT recopilará el resultado y el LOOP devolverá una lista de valores recopilados al salir.

Como ya se mencionó, use WITH-OPEN-FILE en lugar de OPEN/CLOSE. WITH-OPEN-FILE cerrará el archivo al salir del alcance dinámico. No solo por una salida normal, sino también por condiciones de error usando UNWIND-PROTECT.

Si quiere leer el contenido de un archivo, puede usar READ-SEQUENCE. Con los problemas usuales. Por ejemplo, cuando lee un archivo ASCII como texto en una cadena, la cadena puede ser más corta que el archivo. Por ejemplo, Common Lisp representará internamente CRLF con un solo carácter, en plataformas donde CRLF es nueva línea. Otro ejemplo: en implementaciones que admiten Unicode, el código UTF-8 en el archivo se puede reemplazar por un solo carácter.

Answer 3

Voy a añadir bibliotecas en

edición aún más fácil, con uiop, que se incluye en ASDF:.

(uiop:read-file-lines "file.txt") 

https://github.com/fare/asdf/blob/master/uiop/stream.lisp#L445

también tiene

(uiop:read-file-string "file") 

---

Con Alexandria's read-file-into-string y split-secuencia:

(alexandria:read-file-into-string "file.txt") 
(split-sequence:split-sequence #\Newline *) 

Con str:

(str:lines (str:from-file "file.txt"))