Delphi sin bordes y Aplicación Captionless

Question

estoy dispuesto a diseñado una aplicación en Delphi XE2 Borderlessly y Captionlessly usando el siguiente código:

BorderIcons = [] 
    BorderStyle = bsNone 

Pero el problema es que no hay ningún menú en Haga clic derecho sobre la Aplicación de Barra de tareas como en la imagen de arriba. Luego probé los siguientes códigos en el evento FormShow, pero también hay otro problema. Se crea un borde en el lado izquierdo y el lado izquierdo en el lado inferior. Los códigos son:

procedure TForm1.FormShow(Sender: TObject); 
var 
    r: TRect; 
begin 
    r := ClientRect; 
    OffsetRect(r, 0, GetSystemMetrics(SM_CYCAPTION)); 
    OffsetRect(r, GetSystemMetrics(SM_CXFRAME), GetSystemMetrics(SM_CYFRAME)); 
    SetWindowRgn(Handle, 
    CreateRectRgn(
    r.Left, r.Top, 
    ClientWidth + r.Left, ClientHeight + r.Top), True); 

end; 

Por favor, ayúdenme.

Answer 1

Puede hacer lo que David dice y también puede consultar en SetWindowRgn API.

Si usa solo el SetWindowRgn no tiene que quitar el borde del TForm, simplemente haga un rectángulo que comience debajo de él.

Answer 2

La solución simple no es eliminar el menú del sistema en primer lugar. Tenga en cuenta que el menú del sistema es el nombre oficial del menú que falta en su aplicación.

Haga su archivo .dfm aspecto:

BorderIcons = [biSystemMenu] 
BorderStyle = bsNone 

deshacerse de ese código, que no se necesita FormShow.

OK, parece que un fragmento de código de mi experimentación me confundía. Esto es lo que funciona.

hacer exactamente lo que hizo originalmente en su forma .dfm:

BorderIcons = [] 
BorderStyle = bsNone 

A continuación, añadir de nuevo el menú de sistema utilizando CreateParams:

TForm1 = class(TForm) 
protected 
    procedure CreateParams(var Params: TCreateParams); override; 
end; 
... 
procedure TForm1.CreateParams(var Params: TCreateParams); 
begin 
    inherited; 
    Params.Style := Params.Style or WS_SYSMENU; 
end; 

Answer 3

Usted puede tener una ventana que no parece tener una barra de título, o un título estándar, simplemente asumiendo el control de la pintura de toda la ventana:

Cree una nueva aplicación vacía. Utilice este código para el formulario:

unit ncUnit1; 

interface 

// XE2 uses clause 
uses 
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,  
    Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs; 
// If you're not using XE2 take out the prefixes (WinApi, Vcl, System, etc) 

type 
    TForm1 = class(TForm) 
    private 
    { Private declarations } 
    public 
    { Public declarations } 
    protected 
    procedure WMNCPaint(var Message: TWMNCPaint); message WM_NCPAINT; 
    procedure SolidColorNcPaint(solidColor,frameColor:TColor); 
    procedure Resizing(State: TWindowState); override; 


    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

{ TForm1 } 

procedure TForm1.WMNCPaint(var Message: TWMNCPaint); 
begin 
    SolidColorNcPaint(clBtnFace,clBtnFace); 
end; 

procedure TForm1.Resizing(State: TWindowState); 
begin 
    inherited; 
    PostMessage(Self.Handle,WM_NCPAINT,0,0); {force initial paint} 
end; 

procedure TForm1.SolidColorNcPaint(solidColor,frameColor:TColor); 
var 
aBorder:Integer; 
ahdc : HDC; 
begin 
aBorder := GetSystemMetrics(SM_CYSIZEFRAME); 
canvas.Lock; 
ahdc := GetWindowDC(Handle); 
canvas.Handle := ahdc; 
ExcludeClipRect(canvas.Handle, aBorder, 0, Width-aBorder, Height - aBorder) ; 
Canvas.Brush.Style := bsSolid; 
Canvas.Brush.Color := frameColor; 
Canvas.Pen.Color := solidColor; 
Canvas.Rectangle(0,0, Width,Height); 
ReleaseDC(Self.Handle, ahdc); 
canvas.Handle := 0; 
canvas.Unlock; 
end; 


end. 

Lo que ves arriba es sólo el código suficiente para volver a dibujar un color sólido sobre el área no cliente de la ventana, no para eliminarlo por completo. Dependiendo del estilo de la ventana personalizada que desee, debe procesar lo que desee en el formulario. Si no desea un botón Cerrar, quite el botón Cerrar y, si no desea el comportamiento de cambio de tamaño, elimine el comportamiento de cambio de tamaño. Si configura el FormStyle=fsDialog más el código anterior, obtendrá una ventana que tiene un área de título dibujado a medida completa (que puede poner lo que desee). Si realmente no desea que el área del título exista, puede modificar el código anterior para lograr eso también.

Answer 4

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    BorderStyle := bsNone; 
    SetWindowLong(Handle, GWL_STYLE, 
     WS_POPUP or WS_CLIPSIBLINGS or WS_CLIPCHILDREN or WS_SYSMENU); 
    SetWindowLong(Handle, GWL_EXSTYLE, WS_EX_CONTROLPARENT or WS_EX_APPWINDOW); 
end; 

No necesita el código en el controlador OnShow con esta solución.

El código anterior se puede llamar en cualquier momento (no sólo en OnCreate), que puede ser utilizado para alterar el comportamiento de una forma de correr, por ejemplo, (basta con incluir WS_VISIBLE a estilos de ventana si el formulario ya es visible).

Si desea que el comportamiento sea efectivo durante el tiempo de vida del formulario, es mejor configurar los indicadores en un CreateParams modificado (donde VCL aplica los estilos de formulario). Esto también tendrá en cuenta la posibilidad de recreación de la forma. No establecer cualquier propiedad formulario de la OI para esta solución, todas las etiquetas están definidas explícitamente en el código:

type 
    TForm1 = class(TForm) 
    .. 
    protected 
    procedure CreateParams(var Params: TCreateParams); override; 

.. 

procedure TForm1.CreateParams(var Params: TCreateParams); 
begin 
    inherited; 
    Params.Style := WS_POPUP or WS_CLIPSIBLINGS or WS_CLIPCHILDREN or WS_SYSMENU; 
    Params.ExStyle := WS_EX_CONTROLPARENT or WS_EX_APPWINDOW; 
end;