Coincidencia de patrones al comienzo de una cadena en f #

Question

Estoy tratando de hacer coincidir el comienzo de las cadenas en f #. No estoy seguro si tengo que tratarlos como una lista de personajes o qué. Cualquier sugerencia sera apreciada.

Aquí es una versión pseudo código de lo que estoy tratando de hacer

let text = "The brown fox.." 

match text with 
| "The"::_ -> true 
| "If"::_ -> true 
| _ -> false 

Por lo tanto, quiero ir al inicio de la cadena y combinar. Tenga en cuenta que no estoy haciendo coincidir en una lista de cadenas, simplemente escribí lo anterior como una idea de la esencia de lo que estoy tratando de hacer.

Answer 1

Parametrizado active patterns al rescate!

let (|Prefix|_|) (p:string) (s:string) = 
    if s.StartsWith(p) then 
     Some(s.Substring(p.Length)) 
    else 
     None 

match "Hello world" with 
| Prefix "The" rest -> printfn "Started with 'The', rest is %s" rest 
| Prefix "Hello" rest -> printfn "Started with 'Hello', rest is %s" rest 
| _ -> printfn "neither" 

Answer 2

Sí, tiene que tratarlos como una lista de caracteres si desea usar una expresión de coincidencia.

se limita a transformar la cadena con:

let text = "The brown fox.." |> Seq.toList 

A continuación, se puede utilizar una expresión de coincidencia, sino que tendrá que utilizar caracteres (el tipo de elementos en la lista) para cada letra:

match text with 
| 'T'::'h'::'e'::_ -> true 
| 'I'::'f'::_ -> true 
| _ -> false 

Como Brian sugiere Patrones Activos Paramétricos son mucho más agradables, hay algunos patrones útiles here (vaya al final de la página).

Answer 3

También es posible usar un guardia en el patrón:

match text with 
| txt when txt.StartsWith("The") -> true 
| txt when txt.StartsWith("If") -> true 
| _ -> false