¿Cómo busco una colección genérica de TList <T>?

Question

Duplicar posible:
How can I search a generic TList for a record with a certain field value?

tengo una colección de

TList<TActivityCategory> 

TActivityCategory tiene una propiedad Name de tipo cadena y quiero buscar el TList usando el nombre propiedad.

Veo BinarySearch en el TList <> pero eso requeriría una instancia de TActivityCategory. Solo quiero pasar la cadena por un nombre.

¿Cómo voy a hacer esto?

Answer 1

Si no tiene una instancia para buscar, debe hacer su propia búsqueda. Hay tres formas básicas de hacer esto:

• búsqueda binaria: implementar su propia búsqueda binaria. Esto solo funcionará si la lista está ordenada.
• Búsqueda lineal: Implemente su propia búsqueda lineal. Esto siempre funcionará, pero en listas grandes es significativamente más lento que una búsqueda binaria.
• Buscar en el diccionario: Mantener un TDictionary<string, TActivityCategory> junto a la lista. No es necesario realizar búsquedas, aunque debe escribir un código para mantener las dos sincronizadas.

Answer 2

Al crear la lista, puede pasarla a un comparador. Hay algunas clases de comparación en la unidad Generics.Defaults donde puede pasar un método anónimo para comparar dos elementos. Se usan para varios métodos, como IndexOf, Contains u Sort.

Ejemplo:

uses 
    Generics.Defaults, 
    Generics.Collections; 

type 
    TActivityCategory = class 
    private 
    FName: string; 
    public 
    constructor Create(const Name: string); 
    property Name: string read FName write FName; 
    end; 

constructor TActivityCategory.Create(const Name: string); 
begin 
    FName := Name; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    activities: TList<TActivityCategory>; 
    search: TActivityCategory; 
begin 
    activities := TObjectList<TActivityCategory>.Create(
    TDelegatedComparer<TActivityCategory>.Create(
     function(const Left, Right: TActivityCategory): Integer 
     begin 
     Result := CompareText(Left.Name, Right.Name); 
     end)); 

    activities.Add(TActivityCategory.Create('Category B')); 
    activities.Add(TActivityCategory.Create('Category C')); 
    activities.Add(TActivityCategory.Create('Category A')); 

    search := TActivityCategory.Create('Category C'); 
    if activities.Contains(search) then 
    ShowMessage('found'); 

    ShowMessageFmt('Index: %d', [activities.IndexOf(search)]); 
    activities.Sort; 
    ShowMessageFmt('Index: %d', [activities.IndexOf(search)]); 


    search.Name := 'Category D'; 
    if not activities.Contains(search) then 
    ShowMessage('not found'); 

    search.Free; 
    activities.Free; 
end; 

Answer 3

Para ser perfectamente franco, y teniendo en cuenta toda la placa de la caldera requerido para un enfoque basado en el comparador, que sólo puede ser más simple para escribir su propia rutina de búsqueda:

type 
    TActivityCategoryList = class(TList<TActivityCategory>) 
    public 
    function Find(const Name: string): Integer; 
    end; 

function TActivityCategoryList.Find(const Name: string): Integer; 
begin 
    for Result := 0 to Count-1 do 
    if Self[Result].Name=Name then 
     exit; 
    Result := -1; 
end;