gama de ordenación personalizada en Perl

Question

que tiene una matriz de Perl tareas a realizar que tiene este aspecto:

@todos = (
    "1 (A) Complete online final @evm4700 t:2010-06-02", 
    "3 Write thank-you t:2010-06-10", 
    "4 (B) Clean t:2010-05-30", 
    "5 Donate to LSF t:2010-06-02", 
    "6 (A) t:2010-05-30 Pick up dry cleaning", 
    "2 (C) Call Chris Johnson t:2010-06-01" 
); 

Ese primer número es el ID de la tarea. Si una tarea tiene ([A-Z]) junto a, eso define la prioridad de la tarea. Lo que quiero hacer es ordenar la matriz tareas de una manera que coloca los elementos priorizados primera (y en orden de prioridad descendente, de la A - Z):

@todos = (
    "1 (A) Complete online final @evm4700 t:2010-06-02", 
    "6 (A) t:2010-05-30 Pick up dry cleaning", 
    "4 (B) Clean t:2010-05-30", 
    "2 (C) Call Chris Johnson t:2010-06-01" 
    "3 Write thank-you t:2010-06-10", 
    "5 Donate to LSF t:2010-06-02", 
); 

no puedo usar un habitual sort() a causa de esas identificaciones al lado de las tareas, entonces supongo que se necesita algún tipo de subrutina de clasificación personalizada. Sin embargo, mi conocimiento de cómo hacer esto de manera eficiente en Perl es mínimo.

Gracias, todo.

Answer 1

suena como usted desea que el Schwartzian transform:

@todos = 
    map { $_->[0] } 
    sort { $a->[1] cmp $b->[1] or $a->[0] cmp $b->[0] } 
    map { [ $_, /^\d+ \(([[:alpha:]])\)/ ? $1 : "[" ] } 
    @todos; 

"[" es el carácter después de "Z"; dando esta "prioridad" a los elementos sin priorizar será ordenarlos después de los elementos priorizados.

Alternativamente, y tal vez más fácilmente asible:

@todos = 
    map { substr $_, 1 } 
    sort 
    map { (/^\d+ \(([[:alpha:]])\)/ ? $1 : "[") . $_ } 
    @todos; 

Answer 2

Aquí es fija @Sean's solution que utiliza una especie numérica para los ID de tarea (por lo tanto 10a tarea va después del 9 de como debería):

my @sorted_todos = map { $_->[0] } 
    sort { $a->[1][1] cmp $b->[1][1] # A 
         || 
      $a->[1][0] <=> $b->[1][0] # 1 
    } map { [ $_, /^(\d+) \(([[:alpha:]])\)/ ? [$1, $2] : [0, "zz"]] } @todos; 

Answer 3

He aquí una versión que es bastante explícita acerca de cómo funciona:

my @sorted_todos = sort { 
    my ($right_prio) = ($b =~ /^\d+\s+\(([A-Z])\)/); 
    return -1 unless defined $right_prio; 
    my ($left_prio) = ($a =~ /^\d+\s+\(([A-Z])\)/); 
    return 1 unless defined $left_prio; 
    return $left_prio cmp $right_prio; 
} @todos; 

Answer 4

use Sort::Key 'keysort'; 

my @sorted = keysort { /^\d+\s+\(([A-Z])\)/ ? $1 : 'ZZ' } @todos; 

Answer 5

solución mucho más sencilla:

sort {($a =~ /\((.)\)/)[0] cmp ($b =~ /\((.)\)/)[0]} @todos;