¿Cómo puedo usar XML :: LibXML de Perl para extraer un atributo en una etiqueta?

Question

que tienen un archivo XML

<PARENT > 
<TAG string1="asdf" string2="asdf" > 
</TAG > 
</PARENT> 

Quiero extraer el valor string2 aquí .. y también quiero establecer en un valor nuevo ..

Cómo hacer eso?

Answer 1

Uso expresiones XPath

use strict;                              
use warnings;                              

use XML::LibXML;                             
use Data::Dumper;                             

my $doc = XML::LibXML->new->parse_string(q{                      
<PARENT>                               
    <TAG string1="asdf" string2="asdfd">                       
    </TAG>                              
</PARENT>                               
});                                

my $xpath = '/PARENT/TAG/@string2';                        
# getting value of attribute:                          
print Dumper $doc->findvalue($xpath);                        
my ($attr) = $doc->findnodes($xpath);                        

# setting new value:                            
$attr->setValue('dfdsa');                           
print Dumper $doc->findvalue($xpath);                        

# do following if you need to get string representation of your XML structure 
print Dumper $doc->toString(1);        

Y leer la documentación, por supuesto :)

Answer 2

Se podría utilizar XML :: Parser para obtener el valor también. Para obtener más información consulte la XML::Parser documentation:

#!/usr/local/bin/perl 
use strict; 
use warnings; 


use XML::Parser; 
use Data::Dumper; 

my $attributes = {}; 

my $start_handler = sub 
{ 
    my ($expat, $elem, %attr) = @_; 
    if ($elem eq 'TAG') 
    { 
     $attributes->{$attr{'string1'}} = 'Found'; 
    } 
}; 


my $p1 = new XML::Parser(
     Handlers => { 
      Start => $start_handler 
     } 
); 

$p1->parsefile('test.xml'); 

print Dumper($attributes); 

Answer 3

creo que podría ser mejor comenzar con XML::Simple y jugando un poco en primer lugar:

#!/usr/bin/perl 

use strict; 
use warnings; 

use XML::Simple; 

my $xml = XMLin(\*DATA); 

print $xml->{TAG}->{string2}, "\n"; 

$xml->{TAG}->{string2} = "asdf"; 

print XMLout($xml, RootName => 'PARENT'); 

__DATA__ 
<PARENT> 
<TAG string1="asdf" string2="value of string 2"> 
</TAG> 
</PARENT> 

Answer 4

Gracias por sus respuestas. Encontré otra respuesta en "Config file processing with LibXML2" que encontré muy útil.