Llamadas a un método dinámico en una macro Clojure?

Question

Estoy intentando escribir una macro que llamará a los métodos de configuración de Java en función de los argumentos que se le otorguen.

Así, por ejemplo:

(my-macro login-as-fred {"Username" "fred" "Password" "wilma"}) 

podría ampliar a algo como lo siguiente:

(doto (new MyClass) 
    (.setUsername "fred") 
    (.setPassword "wilma")) 

¿Cómo recomendaría hacer frente a esto?

Específicamente, tengo problemas para encontrar la mejor manera de construir el nombre del método setter y hacer que lo interprete como un símbolo en la macro.

Answer 1

Lo bueno de las macros es que en realidad no tienes que profundizar en las clases ni nada de eso. Solo tiene que escribir el código que genera las expresiones s apropiadas.

primer lugar una función para generar una s-expresión como (.setName 42)

(defn make-call [name val] 
    (list (symbol (str ".set" name) val))) 

luego una macro para generar las expresiones y el tapón (~ @) ellos en una expresión doto.

(defmacro map-set [class things] 
    `(doto ~class ~@(map make-call things)) 

Debido a que es una macro que nunca tiene que saber qué clase de lo que está siendo llamado a es ni siquiera que existe la clase en la que se va a utilizar.

Answer 2

Usted tiene que morder la bala y utilizar clojure.lang.Reflector/invokeInstanceMethod así:

(defn do-stuff [obj m] 
    (doseq [[k v] m] 
    (let [method-name (str "set" k)] 
     (clojure.lang.Reflector/invokeInstanceMethod 
     obj 
     method-name 
     (into-array Object [v])))) 
    obj) 

(do-stuff (java.util.Date.) {"Month" 2}) ; use it 

No hay necesidad de una macro (por lo que yo sé, una macro no permitiría eludir la reflexión, o bien, al menos para el caso general).

Answer 3

Alguien (creo que Arthur Ulfeldt) tenía una respuesta publicada que era casi correcta, pero se ha eliminado ahora. Por favor, acéptelo en vez del mío si vuelve a publicar. (O acepte de PMF.) Esta es una versión de trabajo:

(defmacro set-all [obj m] 
    `(doto ~obj ~@(map (fn [[k v]] 
         (list (symbol (str ".set" k)) v)) 
        m))) 

user> (macroexpand-1 '(set-all (java.util.Date.) {"Month" 0 "Date" 1 "Year" 2009})) 
(clojure.core/doto (java.util.Date.) (.setMonth 0) (.setDate 1) (.setYear 2009)) 

user> (set-all (java.util.Date.) {"Month" 0 "Date" 1 "Year" 2009}) 
#<Date Fri Jan 01 14:15:51 PST 3909> 

Answer 4

Por favor, no construyen s-expresiones con list para las macros. Esto dañará seriamente la seguridad de la macro. Es muy fácil cometer un error, que es difícil de rastrear. Por favor use siempre syntax-quote! Aunque, esto no es un problema en este caso, es bueno adquirir el hábito de usar solo sintaxis-quote!

Dependiendo de la fuente de su mapa, también podría considerar el uso de palabras clave como claves para que se vea más parecido a un clojure. Aquí es mi opinión:

(defmacro configure 
    [object options] 
    `(doto ~object 
    ~@(map (fn [[property value]] 
       (let [property (name property) 
        setter (str ".set" 
            (.toUpperCase (subs property 0 1)) 
            (subs property 1))] 
       `(~(symbol setter) ~value))) 
      options)))

Esto puede ser utilizado como:

user=> (macroexpand-1 '(configure (MyClass.) {:username "fred" :password "wilma"})) 
(clojure.core/doto (MyClass.) (.setUsername "fred") (.setPassword "wilma"))