Perl Class :: Falla del accesorio, ejemplo trivial: ¿por qué?

Question

¿Puede alguien decirme por qué el principal no encuentra los métodos generados por Class :: Accessor en este pequeño y trivial ejemplo?

Estas pocas líneas de código fallan con

perl codesnippets/accessor.pl 
Can't locate object method "color" via package "Critter" at 
codesnippets/accessor.pl line 6. 

ver el código:

#!/opt/local/bin/perl 
# The whole Class::Accessor thing does not work !! 

my $a = Critter->new; 
$a->color("blue"); 
$a->display; 
exit 0; 

package Critter; 
    use base qw(Class::Accessor); 
    Critter->mk_accessors ("color"); 

    sub display { 
     my $self = shift; 
     print "i am a $self->color " . ref($self) . ", whatever this word means\n"; 
    } 

Answer 1

FM te está dando un buen consejo. mk_accessors necesita ejecutarse antes que el otro código. Además, normalmente pondría Critter en un archivo separado y use Critter para cargar el módulo.

Esto funciona porque use tiene efectos de tiempo de compilación. Hacer use Critter; es lo mismo que hacer BEGIN { require Critter; Critter->import; } Esto garantiza que el código de inicialización de su módulo se ejecutará incluso antes de que el resto del código se compile.

Es aceptable poner varios paquetes en un solo archivo. A menudo, crearé prototipos de objetos relacionados en un solo archivo, ya que lo tengo todo a mano mientras estoy creando prototipos. También es bastante fácil dividir el archivo en bits separados cuando llegue el momento.

Debido a esto, creo que la mejor manera de mantener varios paquetes en un archivo y trabajar con ellos como si los estuviera usando es colocar las definiciones de paquetes en BEGIN bloques que terminan en un valor verdadero. Usando mi enfoque, su ejemplo se escribiría:

#!/opt/local/bin/perl 

my $a = Critter->new; 
$a->color("blue"); 
$a->display; 

BEGIN { 
    package Critter; 
    use base qw(Class::Accessor); 

    use strict; 
    use warnings; 

    Critter->mk_accessors ("color"); 

    sub display { 
     my $self = shift; 

     # Your print was incorrect - one way: 
     printf "i am a %s %s whatever this word means\n", $self->color, ref $self; 

     # another: 
     print "i am a ", $self->color, ref $self, "whatever this word means\n"; 

    } 

    1; 
} 

Answer 2

Su código está fuera de servicio. Si desea que el accesorio color esté disponible, debe invocar mk_accessorsantes de para crear su objeto y comenzar a hacer cosas con él. Por ejemplo:

package Critter; 
use base qw(Class::Accessor); 
Critter->mk_accessors("color"); 

sub display { 
    my $self = shift; 
    print $self->color, ' ', ref($self), "\n"; 
} 

package main; 
my $c = Critter->new; 
$c->color("blue"); 
$c->display; 

Más comúnmente, el código Critter estaría en su propio módulo (Critter.pm), y toda la magia mk_accessor ocurriría cuando el script principal corre use Critter - mucho antes de su script comienza a trabajar con Critter y Varmint objetos.

Answer 3

Sólo quería ofrecerle una mejor solución - no dude en esta downvote al olvido si la solución no es bienvenido, pero C :: A es realmente una mala idea este día y edad, utilice Moose:

package Critter; 
use Moose; 

has 'color' => (isa => 'Str', is => 'rw'); # Notice, this is typed 

sub display { 
    my $self = shift; 
    printf (
     "i am a %s %s whatever this word means\n" 
     , $self->color 
     , $self->meta->name 
    ); 
} 

package main; 
use strict; 
use warnings; 

my $c = Critter->new; # or my $c = Critter->new({ color => blue }); 
$c->color("blue"); 
$c->display;