usando XSL para reemplazar nodos XML con nodos nuevos

Question

Necesito una solución XSL para reemplazar nodos XML con nodos nuevos.

Digamos que tiene la siguiente estructura XML existente:

<root> 
    <criteria> 
     <criterion>AAA</criterion> 
    </criteria> 
</root> 

Y quiero reemplazar el nodo uno de los criterios con:

<criterion>BBB</criterion> 
<criterion>CCC</criterion> 
<criterion>DDD</criterion> 

Así que el resultado final XML es:

<root> 
    <criteria> 
     <criterion>BBB</criterion> 
     <criterion>CCC</criterion> 
     <criterion>DDD</criterion> 
    </criteria> 
</root> 

He intentado usar subserie-antes y subserie-después para copiar la primera mitad de la estructura, luego ju Copie la segunda mitad (para completar mis nuevos nodos entre las dos mitades) pero parece que las funciones de subcadena solo reconocen el texto entre las etiquetas de los nodos, y no las etiquetas como yo quiero. :(:(

Cualesquiera otras soluciones?

Answer 1

XSL no puede reemplazar nada. Lo mejor que puede hacer es copiar las partes que desea conservar, a continuación, dar salida a las partes que quiera cambiar el lugar de las piezas usted no desea mantener

---

Ejemplo:.

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl" 
> 
    <xsl:output method="xml" indent="yes"/> 

    <!-- This is an identity template - it copies everything 
     that doesn't match another template --> 
    <xsl:template match="@* | node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <!-- This is the "other template". It says to use your BBB-DDD elements 
     instead of the AAA element --> 
    <xsl:template match="criterion[.='AAA']"> 
    <xsl:element name="criterion"> 
     <xsl:text>BBB</xsl:text> 
    </xsl:element> 
    <xsl:element name="criterion"> 
     <xsl:text>CCC</xsl:text> 
    </xsl:element> 
    <xsl:element name="criterion"> 
     <xsl:text>DDD</xsl:text> 
    </xsl:element> 
    </xsl:template> 
</xsl:stylesheet> 

---

La coincidencia de la plantilla @* | node() coincide con cualquier atributo o cualquier otro tipo de nodo. El truco es que las coincidencias de plantillas tienen prioridades. Puedes pensar en la regla como "el partido más específico gana". Cualquier cosa va a ser más específico que "cualquier atributo u otro nodo". Esto hace que la "identidad" coincida con una prioridad muy baja.

Cuando coincide con, simplemente copia cualquier nodo que encuentre dentro del atributo o nodo coincidente.

Cualquier otra plantilla que tenga tendrá una mayor prioridad. Lo que sea que coincidan, es el código dentro de la plantilla más específica que tendrá efecto. Por ejemplo, si simplemente elimina todo lo que está dentro de la plantilla criterion[.='AAA'], encontrará que ha copiado exactamente su entrada, excepto el elemento "AAA".

Answer 2

Bajo la regla general de-más-que-unidireccional a piel-a-cat

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml"/> 
    <xsl:template match="/"> 
     <xsl:apply-templates /> 
    </xsl:template> 
    <!-- 
     when you capture a node with the text 'AAA' 
      emit the BBB, CCC, DDD nodes 
    --> 
    <xsl:template match="criterion[text() = 'AAA']"> 
     <xsl:element name="criterion"> 
      <xsl:text>BBB</xsl:text> 
     </xsl:element> 
     <xsl:element name="criterion"> 
      <xsl:text>CCC</xsl:text> 
     </xsl:element> 
     <xsl:element name="criterion"> 
      <xsl:text>DDD</xsl:text> 
     </xsl:element> 
    </xsl:template> 
    <!-- identity template --> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 3

Aquí es una solución correcta, que es probablemente una de las más cortas:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="criterion[. = 'AAA']"> 
    <criterion>BBB</criterion> 
    <criterion>CCC</criterion> 
    <criterion>DDD</criterion> </xsl:template> 
</xsl:stylesheet> 

Cuando se aplica esta transformación en el documento XML proporcionado, el resultado deseado se produce:

<root> 
    <criteria> 
     <criterion>BBB</criterion> 
     <criterion>CCC</criterion> 
     <criterion>DDD</criterion> 
    </criteria> 
</root> 

hacer la nota:

1. El uso de la plantilla de identidad .

2. Cómo la plantilla de identidad es reemplazada por una plantilla específica - solo para un elemento criterion, cuyo valor de cadena es 'AAA'.