Regex con expresión recursiva para unir llaves anidadas?

Question

Estoy tratando de hacer coincidir texto como sp { ...{...}... }, donde las llaves se pueden anidar. Esto es lo que tengo hasta ahora:

my $regex = qr/ 
(     #save $1 
    sp\s+   #start Soar production 
    (    #save $2 
     \{   #opening brace 
     [^{}]*  #anything but braces 
     \}   #closing brace 
     | (?1)  #or nested braces 
    )+    #0 or more 
) 
/x; 

simplemente no puede conseguir que se corresponde con el siguiente texto: sp { { word } }. ¿Alguien puede ver lo que está mal con mi expresión regular?

Answer 1

Existen numerosos problemas. El bit debe ser recursivo:

(
    (?: \{ (?-1) \} 
    | [^{}]+ 
    )* 
) 

Todos juntos:

my $regex = qr/ 
    sp\s+ 
    \{ 
     (
     (?: \{ (?-1) \} 
     | [^{}]++ 
     )* 
    ) 
    \} 
/x; 

print "$1\n" if 'sp { { word } }' =~ /($regex)/; 

Answer 2

Este es el caso para el Text::Balanced infrautilizada, un módulo básico muy útil para este tipo de cosas. No se basan en la pos del inicio de la secuencia delimitada ser encontrado/set en primer lugar, por lo que suelen alegar ésta como esto:

#!/usr/bin/env perl 

use strict; 
use warnings; 

use Text::Balanced 'extract_bracketed'; 

sub get_bracketed { 
    my $str = shift; 

    # seek to beginning of bracket 
    return undef unless $str =~ /(sp\s+)(?={)/gc; 

    # store the prefix 
    my $prefix = $1; 

    # get everything from the start brace to the matching end brace 
    my ($bracketed) = extract_bracketed($str, '{}'); 

    # no closing brace found 
    return undef unless $bracketed; 

    # return the whole match 
    return $prefix . $bracketed; 
} 

my $str = 'sp { { word } }'; 

print get_bracketed $str; 

la expresión regular con el modificador gc cuenta la cadena de recordar dónde está el punto final de el partido es, y extract_bracketed usa esa información para saber por dónde empezar.