¿Cómo formatear los documentos de resultados de Solr?

Question

Quiero formatear la página de resultados de solr en lugar de solo xml- mostrar a un usuario solo diez resultados a la vez (una página) y proporcionar enlaces para la página de resultados siguiente o anterior.

Y agrega algunos css. ¿dónde y cómo lo hago?

Por favor, guíame. Gracias de antemano.

Answer 1

puede usar el XsltReponseWriter. Que se documenta aquí:

http://wiki.apache.org/solr/XsltResponseWriter

He aquí un ejemplo que convierte resonse de Solr en una fuente Atom:

https://github.com/mauricio/acts_as_solr/blob/master/jetty/solr/conf/xslt/example_atom.xsl

podría utilizar la información de encabezado que Solr proporciona para ayudar con la paginación.

<str name="rows">10</str> 
<result name="response" numFound="8104" start="0"> 

Answer 2

Solo para el registro (esta publicación es muy antigua). Publiqué aquí un archivo XSLT completo que formatea los resultados de Solr, de forma similar a Google (con números de página, etc.).

Su seach Solr, debe tener los siguientes parámetros: hl = en hl.fl = contenido inicio = 0 filas = 10

<?xml version='1.0' encoding='UTF-8'?> 
<xsl:stylesheet version='1.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform'> 
<xsl:output media-type="text/html" encoding="UTF-8"/> 

<!-- Variables para el paginador --> 
<xsl:variable name="pageNumber" select="(response/result/@start div 10) + 1"/> 
<xsl:variable name="numberOfRecords" select="response/result/@numFound"/> 
<xsl:variable name="recordsPerPage" select="/response/lst[@name='responseHeader']/lst[@name='params']/str[@name='rows']" /> 
<xsl:variable name="endPage" select="ceiling(response/result/@numFound div 10)" /> 
<xsl:variable name="cantPages" select="5" /> 
<xsl:variable name="queryPura" select="/response/lst[@name='responseHeader']/lst[@name='params']/str[@name='q']" /> 
<xsl:variable name="query" select="substring-after($queryPura, 'OR ')" /> 

<xsl:key name="preg" match="lst[@name='highlighting']/lst" use="@name"/> 

<xsl:template match="/"> 
<style> 
#resultadoBusqueda em { 
font-weight: bold; 
font-style: normal; 
} 
</style> 
<table id="resultadoBusqueda"> 
     <xsl:for-each select="response/result/doc"> 
     <tr> 
       <td style="padding-bottom: 15px;"> 
         <div style="font-family: arial; font-size: 16px"> 
           <a style="color: #0000cd;" onmouseover="this.style.textDecoration = 'underline';" onmouseout="this.style.textDecoration = 'none';"> 
           <xsl:attribute name="href"><xsl:value-of select="str[@name='url']" /></xsl:attribute> 
             <xsl:if test="not(str[@name='title'])"><xsl:value-of select="str[@name='url']" /></xsl:if> 
             <xsl:value-of select="str[@name='title']"/> 
           </a> 
         </div> 
         <div style="font-family: arial; color: #000000; font-size: 14px;"> 
           <xsl:apply-templates select="key('preg', ./str[@name='id'])" mode="name"/> 
         </div> 
         <div style="font-family: arial; color: #009b00; font-size: 14px;"> 
           <xsl:value-of select="str[@name='url']" /> 
         </div> 
       </td> 
     </tr> 
     </xsl:for-each> 
     <xsl:if test="not(response/result/doc)"> 
       <h4>No hay ning&#250;n resultado que concuerde con su b&#250;squeda</h4> 
     </xsl:if> 

    <!-- Paginador --> 
    <xsl:if test="response/result/doc"> 
     <tr> 
      <td> 
       <xsl:if test="$recordsPerPage &lt; $numberOfRecords"> 
        <xsl:if test="$pageNumber &gt; 1"> 
         <span style="margin-right: 5px;"><a href="?q={$query}&amp;pag={($pageNumber - 2) * $recordsPerPage}">&lt; Anterior</a> |</span> 
        </xsl:if> 
        <xsl:call-template name="numerosPaginas"> 
         <xsl:with-param name="current" select="$pageNumber"/> 
         <xsl:with-param name="max"> 
          <xsl:choose> 
           <xsl:when test="(($pageNumber + $cantPages) &gt; $endPage) or ($endPage &lt;= 9)"> 
            <xsl:value-of select="$endPage" /> 
           </xsl:when> 
           <xsl:otherwise> 
            <xsl:value-of select="($pageNumber + $cantPages)" /> 
           </xsl:otherwise> 
          </xsl:choose> 
         </xsl:with-param> 
         <xsl:with-param name="number"> 
          <xsl:choose> 
           <xsl:when test="(($pageNumber - $cantPages) &lt; 1) or ($endPage &lt;= 9)"> 
            <xsl:value-of select="1" /> 
           </xsl:when> 
           <xsl:otherwise> 
            <xsl:value-of select="($pageNumber - $cantPages)" /> 
           </xsl:otherwise> 
          </xsl:choose> 
         </xsl:with-param> 

        </xsl:call-template> 
        <xsl:if test="(($pageNumber) * $recordsPerPage) &lt; ($numberOfRecords)"> 
          <span style="margin-right: 5px;">| <a href="?q={$query}&amp;pag={($pageNumber) * $recordsPerPage}">Siguiente &gt;</a></span> 
        </xsl:if> 
        <span style="margin-right: 5px;">(Resultados encontrados: <xsl:value-of select="$numberOfRecords" />)</span> 
       </xsl:if> 
      </td> 
     </tr> 
    </xsl:if> 
</table> 
</xsl:template> 

<xsl:template match="arr/str" mode="name"> 
     <xsl:value-of select="." disable-output-escaping="yes" /> 
</xsl:template> 

<!-- Numeracion de los paginadores --> 
<xsl:template name="numerosPaginas"> 
    <xsl:param name="current"/> 
    <xsl:param name="number"/> 
    <xsl:param name="max"/> 

    <xsl:choose> 
     <xsl:when test="$number = $current"> 
      <!-- Show current page without a link --> 
      <span class="current" style="margin-right: 5px;"> 
       <xsl:value-of select="$number"/> 
      </span> 
     </xsl:when> 
     <xsl:otherwise> 
      <span style="margin-right: 5px;"> 
       <a href="?q={$query}&amp;pag={($number - 1) * $recordsPerPage}"><xsl:value-of select="$number"/></a> 
      </span> 
     </xsl:otherwise> 
    </xsl:choose> 

    <!-- Recursively call the template untill we reach the max number of pages --> 
    <xsl:if test="$number &lt; $max"> 
     <xsl:call-template name="numerosPaginas"> 
      <xsl:with-param name="current" select="$current"/> 
      <xsl:with-param name="number" select="$number+1"/> 
      <xsl:with-param name="max" select="$max"/> 
     </xsl:call-template> 
    </xsl:if> 
</xsl:template> 


</xsl:stylesheet> 

Answer 3

Ankit u puede añadir a ese archivo XSL en conf/La carpeta xslt es útil para ti.

pls refieren que http://wiki.apache.org/solr/XsltResponseWriter