En clojure, cómo aplicar una función a los elementos seleccionados en un vector [gran]

Question

Tengo un vector v

(def v [1 2 5 8 4 3 8 9 3]) 

quiero aplicar la función myfn

(defn myfn [x] (+ 1 x)) 

a los elementos seleccionados que yo sus índices han idx

(def idx [3 5]) 

que he visto How do I modify a portion of a vector in Clojure? y no es exactamente lo que necesito.

Al igual que lo que se hace en MATLAB

v = [1 2 5 8 9 3]; 
idx = [3 5]; 
v(idx) = myfn(v(idx)); 

Answer 1

vectores en clojure son asociativos, por lo que puede hacer algo como esto: (reduce #(update-in %1 [%2] myfn) v idx)

Answer 2

Actualizado porque malinterpretado la pregunta.

Aquí hay otra solución:

(apply assoc v (mapcat #(vector % (myfn (v %))) idx)) 

, es decir, construir una lista de argumentos de pares índice/nuevo valor a assoc. Creo que las soluciones de mange probablemente sean mejores.

---

original, solución incorrecta

No se olvide que el vector v es en sí mismo una función de sus índices. Por lo tanto:

(map myfn (map v idx)) 

o:

(->> idx (map v) (map myfn)) 

o:

(map (comp myfn v) idx) 

Estoy seguro de que hay también una respuesta muy inteligente que implica juxt :)

Answer 3

usted menciona "un [ vector grande ", ¿te preocupa el rendimiento? Es posible que desee obtener información sobre transients:

(persistent! 
    (reduce (fn [v i] (assoc! v i (myfn (get v i)))) 
      (transient v) 
      idx)) 

O, si usted prefiere el estilo de bucle, esto hace lo mismo:

(loop [v (transient v), [i & is :as idx] idx] 
    (if (empty? idx) 
    (persistent! v) 
    (recur (assoc! v i (myfn (get v i))) is))) 

Answer 4

(let [sidx (set idx)] 
    (vec      ;(sidx i) 
    (map-indexed (fn [i x] (if (contains? sidx i) (myfn x) x)) v)))