T-SQL obtener el valor seleccionado de procedimiento almacenado

Question

En T-SQL, esto está permitido:

DECLARE @SelectedValue int 
SELECT @SelectedValue = MyIntField FROM MyTable WHERE MyPrimaryKeyField = 1 

lo tanto, es posible obtener el valor de un SELECT y meterlo en una variable (siempre y cuando sea escalar, obviamente).

Si pongo la misma lógica de selección en un procedimiento almacenado:

CREATE PROCEDURE GetMyInt 
AS 
SELECT MyIntField FROM MyTable WHERE MyPrimaryKeyField = 1 

¿Puedo obtener la salida de este procedimiento almacenado y esas cosas en una variable?

Algo así como:

DECLARE @SelectedValue int 
SELECT @SelectedValue = EXEC GetMyInt 

(Sé que la sintaxis anterior no está permitido porque lo probé!)

Answer 1

hay tres maneras de usar: el valor de retorno, y el parámetro de salida y un conjunto de resultados

También, ten cuidado si utilice el patrón: SELECT @Variable=column FROM table ...

si hay múltiples filas devueltas de la consulta, su @Variable solo contendrá el valor de la última fila devuelta por la consulta.

VALOR DEVUELTO
ya que la consulta devuelve un campo int, por lo menos en función de cómo lo nombró. se puede utilizar este truco:

CREATE PROCEDURE GetMyInt 
(@Param int) 
AS 
DECLARE @ReturnValue int 

SELECT @ReturnValue=MyIntField FROM MyTable WHERE MyPrimaryKeyField = @Param 
RETURN @ReturnValue 
GO 

y ahora llamar a su procedimiento, tales como:

DECLARE @SelectedValue int 
     ,@Param   int 
SET @Param=1 
EXEC @SelectedValue = GetMyInt @Param 
PRINT @SelectedValue 

esto sólo funcionará para intercepciones, porque RETORNO sólo puede devolver un solo valor int y los nulos se convierten en un cero .

parámetro de salida
puede utilizar un parámetro de salida:

CREATE PROCEDURE GetMyInt 
(@Param  int 
,@OutValue int OUTPUT) 
AS 
SELECT @OutValue=MyIntField FROM MyTable WHERE MyPrimaryKeyField = @Param 
RETURN 0 
GO 

y ahora llamar a su procedimiento, tales como:

DECLARE @SelectedValue int 
     ,@Param   int 
SET @Param=1 
EXEC GetMyInt @Param, @SelectedValue OUTPUT 
PRINT @SelectedValue 

Los parámetros de salida sólo puede devolver un valor, pero puede ser cualquier tipo de datos

RESULTADO DE CONFIGURACIÓN para un conjunto de resultados que el procedimiento sea como:

CREATE PROCEDURE GetMyInt 
(@Param  int) 
AS 
SELECT MyIntField FROM MyTable WHERE MyPrimaryKeyField = @Param 
RETURN 0 
GO 

usarlo como:

DECLARE @ResultSet table (SelectedValue int) 
DECLARE @Param int 
SET @Param=1 
INSERT INTO @ResultSet (SelectedValue) 
    EXEC GetMyInt @Param 
SELECT * FROM @ResultSet 

conjuntos de resultados pueden tener muchas filas y muchas columnas de cualquier tipo de datos

Answer 2

Se necesitaría utilizar valores de retorno.

DECLARE @SelectedValue int 

CREATE PROCEDURE GetMyInt (@MyIntField int OUTPUT) 
AS 
SELECT @MyIntField = MyIntField FROM MyTable WHERE MyPrimaryKeyField = 1 

Entonces lo llaman así:

EXEC GetMyInt OUTPUT @SelectedValue 

Answer 3

Trate de hacer esto:

EXEC @SelectedValue = GetMyInt 

Answer 4

También hay una combinación, puede usar un valor de retorno con un conjunto de registros:

--Stored Procedure--

CREATE PROCEDURE [TestProc] 

AS 
BEGIN 

    DECLARE @Temp TABLE 
    (
     [Name] VARCHAR(50) 
    ) 

    INSERT INTO @Temp VALUES ('Mark') 
    INSERT INTO @Temp VALUES ('John') 
    INSERT INTO @Temp VALUES ('Jane') 
    INSERT INTO @Temp VALUES ('Mary') 

    -- Get recordset 
    SELECT * FROM @Temp 

    DECLARE @ReturnValue INT 
    SELECT @ReturnValue = COUNT([Name]) FROM @Temp 

    -- Return count 
    RETURN @ReturnValue 

END 

--Calling Code--

DECLARE @SelectedValue int 
EXEC @SelectedValue = [TestProc] 

SELECT @SelectedValue 

--Results--