¿Cómo buscar diferentes tipos de archivos usando FindFirst?

Question

en mi solicitud que utilizar el siguiente procedimiento para escanear de forma recursiva cualquier carpeta y subcarpetas, si la carpeta contiene archivos de texto (* .txt) agrego el nombre del archivo a un TStringList definido en mi procedimiento:

procedure FileSearch(const PathName: string; var lstFiles: TStringList); 
const 
    FileMask = '*.txt'; 
var 
    Rec: TSearchRec; 
    Path: string; 
begin 
    Path := IncludeTrailingBackslash(PathName); 
    if FindFirst(Path + FileMask, faAnyFile - faDirectory, Rec) = 0 then 
    try 
     repeat 
     lstFiles.Add(Path + Rec.Name); 
     until FindNext(Rec) <> 0; 
    finally 
     FindClose(Rec); 
    end; 

    if FindFirst(Path + '*.*', faDirectory, Rec) = 0 then 
    try 
     repeat 
     if ((Rec.Attr and faDirectory) <> 0) and (Rec.Name <> '.') and 
      (Rec.Name <> '..') then 
      FileSearch(Path + Rec.Name, lstFiles); 
     until FindNext(Rec) <> 0; 
    finally 
     FindClose(Rec); 
    end; 
end; 

todo funciona perfecto, pero quiero poder buscar múltiples extensiones de archivo. He intentado modificar FileMask para hacerlo, pero cada vez no devuelve nada, probablemente porque está buscando una extensión no válida. He tratado de cada uno de los siguientes, pero sin suerte: (probado uno a la vez, obviamente, yo no escribí las líneas de abajo 3 veces en mi procedimiento)

FileMask = '*.txt|*.rtf|*.doc'; 

FileMask = '*.txt;*.rtf;*.doc'; 

FileMask = '*.txt,*.rtf,*.doc'; 

me siento tonta por preguntar esto, pero ¿cómo puedo permitir que las extensiones de archivo adicionales se incluyan en la búsqueda? Puedo hacerlo para los cuadros de diálogo Abrir y Guardar, ¿por qué no puedo separar las extensiones aquí?

Gracias.

Craig.

Answer 1

Cambie su función para que también acepte una lista de extensiones, separadas por punto y coma o algún otro delimitador. Luego puede verificar la existencia de la extensión de cada archivo encontrado en esa lista de extensiones, y si se encuentra, agréguelo a su lista de cadenas.

Algo como esto debería funcionar: Llamada

procedure FileSearch(const PathName: string; const Extensions: string; 
var lstFiles: TStringList); 
const 
    FileMask = '*.*'; 
var 
    Rec: TSearchRec; 
    Path: string; 
begin 
    Path := IncludeTrailingBackslash(PathName); 
    if FindFirst(Path + FileMask, faAnyFile - faDirectory, Rec) = 0 then 
    try 
     repeat 
     if AnsiPos(ExtractFileExt(Rec.Name), Extensions) > 0 then 
      lstFiles.Add(Path + Rec.Name); 
     until FindNext(Rec) <> 0; 
    finally 
     SysUtils.FindClose(Rec); 
    end; 

    if FindFirst(Path + '*.*', faDirectory, Rec) = 0 then 
    try 
     repeat 
     if ((Rec.Attr and faDirectory) <> 0) and (Rec.Name <> '.') and 
      (Rec.Name <> '..') then 
      FileSearch(Path + Rec.Name, Extensions, lstFiles); 
     until FindNext(Rec) <> 0; 
    finally 
     FindClose(Rec); 
    end; 
end; 

muestra:

FileSearch('C:\Temp', '.txt;.tmp;.exe;.doc', FileList); 

Answer 2

En Delphi XE7 esta línea de código genera (línea 17) un error:

finally 
    SysUtils.FindClose(Rec); 
end; 

Para corrija el error que acabo de eliminar SysUtils. para leer este código:

finally 
    FindClose(Rec); 
end; 

Ahora el código compila bien. Gracias por este código y solución tan útil.