Controlar el nivel de zoom de WinForms utilizando la rueda del mouse sroll y Ctrl en VB.NET

Question

Si tengo un formulario de win, puedo saber cómo puedo controlar el nivel de zoom de la fuente en la aplicación (así como la ventana de la aplicación en sí) usando Ctrl + Mouse Scroll Wheel? Veo que hay un Delta en el evento Scroll Wheel, pero no estoy seguro de cómo funciona. ¿Hay algún ejemplo de código que pueda examinar?

¡Muchas gracias por toda la ayuda!

Answer 1

Vas a tener que controlar el evento KeyDown y KeyUp con el fin de determinar si o no Ctrl clave está siendo presionado. Este valor debe almacenarse a nivel de clase porque será utilizado por otras subrutinas además de los eventos KeyDown y KeyUp.

Luego, escribe el código para manejar el evento MouseWheel del formulario. Desplazarse hacia abajo (hacia usted) causa un valor negativo para la propiedad Delta del MouseEventArgs. Desplazarse hacia arriba es, obviamente, al revés. El valor de la propiedad Delta siempre es actualmente motivo 120.

de Microsoft para este valor es el siguiente:

Actualmente, un valor de 120 es el estándar para un fiador. Si se introducen ratones de mayor resolución, la definición de WHEEL_DELTA podría reducirse. La mayoría de las aplicaciones deben verificar un valor positivo o negativo en lugar de un total agregado.

En su contexto, solo comprobará la señal del Delta y realizará una acción.

Aquí hay un código de ejemplo la implementación básica 'zoom' funcionalidad:

Public Class Form1 
    Enum ZoomDirection 
     None 
     Up 
     Down 
    End Enum 

    Dim CtrlIsDown As Boolean 
    Dim ZoomValue As Integer 

    Sub New() 

     ' This call is required by the designer. 
     InitializeComponent() 

     ' Add any initialization after the InitializeComponent() call. 
     ZoomValue = 100 
    End Sub 

    Private Sub Form1_KeyDown_KeyUp(ByVal sender As Object, _ 
            ByVal e As KeyEventArgs) _ 
       Handles Me.KeyDown, Me.KeyUp 

     CtrlIsDown = e.Control 
    End Sub 

    Private Sub Form1_MouseWheel(ByVal sender As Object, 
           ByVal e As MouseEventArgs) _ 
       Handles Me.MouseWheel 

     'check if control is being held down 
     If CtrlIsDown Then 
      'evaluate the delta's sign and call the appropriate zoom command 
      Select Case Math.Sign(e.Delta) 
       Case Is < 0 
        Zoom(ZoomDirection.Down) 
       Case Is > 0 
        Zoom(ZoomDirection.Up) 
       Case Else 
        Zoom(ZoomDirection.None) 
      End Select 
     End If 
    End Sub 

    Private Sub Zoom(ByVal direction As ZoomDirection) 
     'change the zoom value based on the direction passed 

     Select Case direction 
      Case ZoomDirection.Up 
       ZoomValue += 1 
      Case ZoomDirection.Down 
       ZoomValue -= 1 
      Case Else 
       'do nothing 
     End Select 

     Me.Text = ZoomValue.ToString() 
    End Sub 
End Class 

leer en el siguiente para obtener más información acerca de su pregunta:

1. MSDN: Control.KeyDown Event
2. MSDN: Control.KeyUp Event
3. MSDN: Control.MouseWheel Event
4. MSDN: MouseEventArgs Class

Answer 2

sospecho que puede simplemente prueba:

(VB.NET):

If (ModifierKeys And Keys.Control) = Keys.Control Then 

(C#):

if((ModifierKeys & Keys.Control) == Keys.Control) 

permite comprobar si la clave es el control abajo.