Cómo usar sed para eliminar solo las líneas dobles vacías?

Question

Encontré esto question and answer sobre cómo eliminar las líneas triples vacías. Sin embargo, necesito lo mismo solo para líneas dobles vacías. Es decir. todas las líneas dobles en blanco deben borrarse por completo, pero deben conservarse líneas en blanco individuales.

Conozco un poco de sed, pero el comando propuesto para la eliminación de líneas en blanco triple es sobre mi cabeza:

sed '1N;N;/^\n\n$/d;P;D'

Answer 1

he comentado el comando sed no entiende:

sed ' 
    ## In first line: append second line with a newline character between them. 
    1N; 
    ## Do the same with third line. 
    N; 
    ## When found three consecutive blank lines, delete them. 
    ## Here there are two newlines but you have to count one more deleted with last "D" command. 
    /^\n\n$/d; 
    ## The combo "P+D+N" simulates a FIFO, "P+D" prints and deletes from one side while "N" appends 
    ## a line from the other side. 
    P; 
    D 
' 

Retire 1N porque necesitamos sólo dos líneas en la 'pila' y es enought con el segundo N, y cambiar /^\n\n$/d;-/^\n$/d; para eliminar las dos líneas en blanco consecutivas.

Una prueba:

contenido de infile:

1 


2 
3 

4 



5 

6 


7 

Ejecutar el comando sed:

sed ' 
    N; 
    /^\n$/d; 
    P; 
    D 
' infile 

que los rendimientos:

1 
2 
3 

4 

5 

6 
7 

Answer 2

Esto se ab e más fácil con awk:

awk -v RS='\n\n\n' 1 

Answer 3

sed '/^$/{N;/^\n$/d;}' 

Se borrará sólo dos líneas en blanco consecutivos en un archivo. Puede usar esta expresión solo en el archivo, entonces solo usted puede comprender completamente. Cuando llegue una línea en blanco, entrará en llaves.

Normalmente, sed leerá una línea. N agregará la segunda línea al espacio del patrón. Si esa línea es línea vacía. las dos líneas están separadas por nueva línea.

/^\n$/ este patrón coincidirá con el tiempo que solo el d funcionará. Else d no funciona. d se utiliza para eliminar el espacio de patrón de todo el contenido y luego iniciar el siguiente ciclo.

Answer 4

Esto sería más fácil con cat:

cat -s 

Answer 5

Sólo tubería a comandos 'uniq' y todas las líneas vacías sin importar el número de ellos se redujeron a sólo uno. Más simple es mejor.

Aclaración: como dijo Marlar, esto no es una solución si tiene "otras líneas duplicadas consecutivas no en blanco" de las que no desea deshacerse. Esta es una solución en otros casos, como cuando trato de limpiar los archivos de configuración, que era la solución que estaba buscando cuando vi esta pregunta. Solucioné mi problema simplemente usando 'uniq'.