¿Cómo abrir una URL con el navegador predeterminado con las aplicaciones multiplataforma de FireMonkey?

Question

Generalmente, utilizo: ShellExecute(0, 'OPEN', PChar(edtURL.Text), '', '', SW_SHOWNORMAL);

¿Cómo puedo tener el mismo comportamiento (la apertura de un enlace en el navegador por defecto), en todas las plataformas (Windows y OSX)?

Answer 1

En el foro de discusión FireMonkey me encontré con este código para una consulta sobre NSWorkspace.URLForApplicationToOpenURL:

uses 
    Posix.Stdlib; 
.... 
    _system(PAnsiChar('open ' + ACommand)); 

(no probado por mí)

---

actualización: Posix no está disponible en Windows, por lo que no es posible escribir una solución que use las mismas llamadas al sistema operativo en todas las plataformas. Sugiero mover dicho código en una unidad central de 'XPlatform' que tenga algunos IFDEF POSIX, etc.

Answer 2

Respecto a la respuesta de mjn, he escrito la siguiente unidad. Lo probé con éxito en Windows, pero no tengo un OSX para probarlo en esta plataforma. Si alguien puede confirmar que funciona, lo agradecería.

unit fOpen; 

interface 

uses 
{$IFDEF MSWINDOWS} 
    Winapi.ShellAPI, Winapi.Windows; 
{$ENDIF MSWINDOWS} 
{$IFDEF POSIX} 
    Posix.Stdlib; 
{$ENDIF POSIX} 

type 
    TMisc = class 
    class procedure Open(sCommand: string); 
    end; 

implementation 

class procedure TMisc.Open(sCommand: string); 
begin 
{$IFDEF MSWINDOWS} 
    ShellExecute(0, 'OPEN', PChar(sCommand), '', '', SW_SHOWNORMAL); 
{$ENDIF MSWINDOWS} 
{$IFDEF POSIX} 
    _system(PAnsiChar('open ' + AnsiString(sCommand))); 
{$ENDIF POSIX} 
end; 

end. 

y yo lo llaman así:

TMisc.Open('https://stackoverflow.com/questions/7443264/how-to-open-an-url-with-the-default-browser-with-firemonkey-cross-platform-applic'); 

Answer 3

Y ahora un C++ versión (código OSx no probado, tampoco estoy seguro de la #DEF _POSIX):

#ifdef _Windows 
#include <Winapi.Windows.hpp> 
#endif // _Windows 
#ifdef _POSIX 
#include <Posix.Stdlib.h> 
#endif // _POSIX 

void OpenCommand(String _sCommand) 
{ 
    #ifdef _Windows 
    ShellExecute(0, _T("open"), _sCommand.c_str(), _T(""), _T(""), SW_SHOWNORMAL); 
    #endif // _Windows 
    #ifdef _POSIX 
    _system(AnsiString("open " + AnsiString(_sCommand)).c_str()); 
    #endif // _POSIX 
} 

Answer 4

XE2 C++ código probado con éxito (Windows 7 64 y OSX Lion), mejoras menores. Whiler de agradecimiento, el dolor es más :)

#include <fmx.h> 
// --------------------------------------------------------------------------- 
#ifdef _WIN32 
#include <shellapi.h> 
#endif// Windows 
#ifdef TARGET_OS_MAC 
#include <Posix.Stdlib.hpp> 
#endif // Mac 

void OpenCommand(String _sCommand) { 
    #ifdef _Windows 
    String open = "open"; 
    ShellExecute(0, open.w_str(), _sCommand.c_str(), NULL, NULL, SW_SHOWNORMAL); 
    #endif // Windows 

    #ifdef TARGET_OS_MAC 
    system(AnsiString("open " + AnsiString(_sCommand)).c_str()); 
    #endif // Mac 
} 

Answer 5

_system(PAnsiChar('open ' + AnsiString(sCommand))); 

no funciona si cadena de dirección URL (sCommand) incluye carbón comercial (&), necesarios para especificar muchos argumentos en cadena de consulta.

URL enviada a def. el navegador en OSX (Safari) se trunca en la primera aparición de &.

Answer 6

Como se menciona @NicoBlu, la solución aceptada parece truncar la URL después de la primera aparición de '&'. Aquí es lo que funciona para mí sin truncamiento:

uses Macapi.AppKit, Macapi.Foundation, Macapi.Helpers; 

// ... 

procedure OpenLinkInDefaultBrowser(const Link: string); 
    var URL : NSURL; 
     Workspace : NSWorkspace; 
begin 
    URL := TNSURL.Wrap(TNSURL.OCClass.URLWithString(StrToNSStr(Link))); 
    Workspace := TNSWorkspace.Wrap(TNSWorkspace.OCClass.sharedWorkspace); 
    Workspace.openURL(URL); 
end; 

Answer 7

LEncodedString : String; 

begin 
    LEncodedString := TIdURI.URLEncode('http://www.malcolmgroves.com'); 
    sharedApplication.openURL(StringToNSURL(LEncodedString)); 
end; 

Answer 8

Para todas las plataformas (Windows, MacOS, iOS y Android), puede utilizar la unidad que escribí para my blog

unit u_urlOpen; 

interface 

uses 
    System.SysUtils, System.Types, System.UITypes, System.Classes, 
    System.Variants, 
{$IF Defined(IOS)} 
    macapi.helpers, iOSapi.Foundation, FMX.helpers.iOS; 
{$ELSEIF Defined(ANDROID)} 
Androidapi.JNI.GraphicsContentViewText, 
    Androidapi.JNI.Net, 
    Androidapi.JNI.App, 
    Androidapi.helpers; 
{$ELSEIF Defined(MACOS)} 
Posix.Stdlib; 
{$ELSEIF Defined(MSWINDOWS)} 
Winapi.ShellAPI, Winapi.Windows; 
{$ENDIF} 

type 
    tUrlOpen = class 
    class procedure Open(URL: string); 
    end; 

implementation 

class procedure tUrlOpen.Open(URL: string); 
{$IF Defined(ANDROID)} 
var 
    Intent: JIntent; 
{$ENDIF} 
begin 
{$IF Defined(ANDROID)} 
    Intent := TJIntent.Create; 
    Intent.setAction(TJIntent.JavaClass.ACTION_VIEW); 
    Intent.setData(StrToJURI(URL)); 
    tandroidhelper.Activity.startActivity(Intent); 
    // SharedActivity.startActivity(Intent); 
{$ELSEIF Defined(MSWINDOWS)} 
    ShellExecute(0, 'OPEN', PWideChar(URL), nil, nil, SW_SHOWNORMAL); 
{$ELSEIF Defined(IOS)} 
    SharedApplication.OpenURL(StrToNSUrl(URL)); 
{$ELSEIF Defined(MACOS)} 
    _system(PAnsiChar('open ' + AnsiString(URL))); 
{$ENDIF} 
end; 

end.