str_replace en Lisp?

Question

¿Hay alguna función similar a str_replace de PHP en Lisp?

http://php.net/manual/en/function.str-replace.php

Answer 1

Hay una biblioteca llamada CL-ppcre:

(cl-ppcre:regex-replace-all "qwer" "something to qwer" "replace") 
; "something to replace" 

instalarlo a través de quicklisp.

Answer 2

Creo que no hay tal función en el estándar. Si no desea utilizar una expresión regular (CL-ppcre), se puede usar esto:

(defun string-replace (search replace string &optional count) 
    (loop for start = (search search (or result string) 
          :start2 (if start (1+ start) 0)) 
     while (and start 
        (or (null count) (> count 0))) 
     for result = (concatenate 'string 
            (subseq (or result string) 0 start) 
            replace 
            (subseq (or result string) 
              (+ start (length search)))) 
     do (when count (decf count)) 
     finally (return-from string-replace (or result string)))) 

EDIT: Shin Aoyama señaló que esto no funciona para la sustitución, por ejemplo, "\"" con "\\\"" en "str\"ing". Ya que ahora considero que lo anterior como bastante engorroso que debería proponer la implementación dada en el Common Lisp Cookbook, lo cual es mucho mejor:

(defun replace-all (string part replacement &key (test #'char=)) 
    "Returns a new string in which all the occurences of the part 
is replaced with replacement." 
    (with-output-to-string (out) 
    (loop with part-length = (length part) 
      for old-pos = 0 then (+ pos part-length) 
      for pos = (search part string 
          :start2 old-pos 
          :test test) 
      do (write-string string out 
          :start old-pos 
          :end (or pos (length string))) 
      when pos do (write-string replacement out) 
      while pos))) 

me gusta especialmente el uso de with-output-to-string, que generalmente funciona mejor que concatenate.