equivalente de Perl de `rechazo!` De Ruby?

Question

Necesito caminar sobre una matriz y eliminar elementos condicionalmente en Perl. Sé acerca de slice, pero no estoy seguro de cómo usarlo en un contexto foreach.

En Ruby, no es reject!:

foo = [2, 3, 6, 7] 
foo.reject! { |x| x > 3 } 
p foo # outputs "[2, 3]" 

¿Hay un equivalente de Perl?

Answer 1

@foo = (2, 3, 6, 7); 
@foo = grep { $_ <= 3 } @foo; 
print @foo; # 23 

Answer 2

vinko@parrot:/home/vinko# more reject.pl 
my @numbers = (2, 3, 6 ,7); 
print join(",", grep { $_ <= 3 } @numbers)."\n"; 

vinko@parrot:/home/vinko# perl reject.pl 
2,3 

Answer 3

Como las otras respuestas sugieren, grep es normalmente todo lo que necesita.

Sin embargo, es posible con el Perl prototypes para codificar una función que, como el de rubí Array#reject!:

• acepta un bloque
• puede modificar su matriz de argumentos en su lugar

Uso es:

@foo = (2, 3, 6, 7);   # Void context - modify @foo in place 
reject { $_ > 3 } @foo;   # @foo is now (2, 3) 

@foo = (2, 3, 6, 7);   # Scalar context - modify @foo in place 
$n = reject { $_ > 3 } @foo; # @foo is now (2, 3), $n is length of modified @foo 

@foo = (2, 3, 6, 7);   # Array context - return a modified copy of @foo 
@cpy = reject { $_ > 3 } @foo; # @cpy is (2, 3), @foo is (2, 3, 6, 7) 

Implementación:

sub reject(&\@) { 
    my ($block, $ary) = @_; 

    # Return a copy in an array context 
    return grep {! $block->() } @$ary if wantarray; 

    # Otherwise modify in place. Similar to, but not 
    # quite, how rb_ary_reject_bang() does it. 
    my $i = 0; 
    for (@$ary) { 
      next if $block->(); 
      ($ary->[$i], $_) = ($_, $ary->[$i]); # swap idiom to avoid copying 
      $i++;        # possibly huge scalar 
    } 
    $#$ary = $i - 1; # Shorten the input array 

    # We differ from Array#reject! in that we return the number of 
    # elements in the modified array, rather than an undef value if 
    # no rejections were made 
    return scalar(@$ary) if defined(wantarray); 
}