Cómo recupero el sufijo ordinal de un entero en Perl (como st, nd, rd, th)

Question

Tengo el número y necesito agregar el sufijo: 'st', 'nd', 'rd', 'th'. Entonces, por ejemplo: si el número es 42, el sufijo es 'nd', 521 es 'st' y 113 es 'th', y así sucesivamente. Necesito hacer esto en Perl. Cualquier puntero.

Answer 1

Prueba esto:

my $ordinal; 
if ($foo =~ /(?<!1)1$/) { 
    $ordinal = 'st'; 
} elsif ($foo =~ /(?<!1)2$/) { 
    $ordinal = 'nd'; 
} elsif ($foo =~ /(?<!1)3$/) { 
    $ordinal = 'rd'; 
} else { 
    $ordinal = 'th'; 
} 

Answer 2

Uso Lingua::EN::Numbers::Ordinate. A partir de la sinopsis:

use Lingua::EN::Numbers::Ordinate; 
print ordinate(4), "\n"; 
# prints 4th 
print ordinate(-342), "\n"; 
# prints -342nd 

# Example of actual use: 
... 
for(my $i = 0; $i < @records; $i++) { 
    unless(is_valid($record[$i]) { 
    warn "The ", ordinate($i), " record is invalid!\n"; 
    next; 
    } 
    ... 
} 

Answer 3

probar este breve subrutina

use strict; 
use warnings; 

sub ordinal { 
    return $_.(qw/th st nd rd/)[/(?<!1)([123])$/ ? $1 : 0] for int shift; 
} 

for (42, 521, 113) { 
    print ordinal($_), "\n"; 
} 

salida

42nd 
521st 
113th 

Answer 4

he aquí una solución which I originally wrote for a code golf challenge, ligeramente reescrito para ajustarse a las mejores prácticas habituales de código no-golf :

$number =~ s/(1?\d)$/$1 . ((qw'th st nd rd')[$1] || 'th')/e; 

La forma en que funciona es que la expresión regular (1?\d)$ coincide con el último dígito del número, más el dígito anterior si es 1. La sustitución utiliza los dígitos coincidentes como índice de la lista (qw'th st nd rd'), asignando 0 a th, 1 a st, 2 a nd, 3 a rd y cualquier otro valor a undef. Finalmente, el operador || reemplaza undef por th.

Si no te gusta s///e, básicamente se puede escribir la misma solución, p. de esta manera:

for ($number) { 
    /(1?\d)$/ or next; 
    $_ .= (qw'th st nd rd')[$1] || 'th'; 
} 

o como una función:

sub ordinal ($) { 
    $_[0] =~ /(1?\d)$/ or return; 
    return $_[0] . ((qw'th st nd rd')[$1] || 'th'); 
} 

Answer 5

Otra solución (aunque me gusta las respuestas preexistentes que son independientes de la utilización de módulos mejores):

use Date::Calc 'English_Ordinal'; 
print English_Ordinal $ARGV[0];