Usando variables en XmlSlurper's GPath

Question

¿Hay alguna manera de que XmlSlurper obtenga elementos arbitrarios a través de una variable? p. por lo que puedo hacer algo como archivo de entrada :

<file> 
    <record name="some record" /> 
    <record name="some other record" /> 
</file> 

def xml = new XmlSlurper().parse(inputFile) 
String foo = "record" 
return xml.{foo}.size() 

He intentado usar {} y {} $ y() ¿cómo escapar de las variables de ese tipo? ¿O no hay una manera? y ¿es posible usar los resultados de los cierres como los argumentos también? Así que podría hacer algo como

String foo = file.record 
int numRecords = xml.{foo.find(/.\w+$/)} 

Answer 1

import groovy.xml.* 

def xmltxt = """<file> 
    <record name="some record" /> 
    <record name="some other record" /> 
</file>""" 

def xml = new XmlSlurper().parseText(xmltxt) 
String foo = "record" 
return xml."${foo}".size() 

Answer 2

Esta respuesta ofrece un ejemplo de código, y debe mucho al comentario de John W en su respuesta.

Considera:

import groovy.util.* 

def xml = """<root> 
    <element1>foo</element1> 
    <element2>bar</element2> 
    <items> 
    <item> 
     <name>a</name> 
     <desc>b</desc> 
    </item> 
    <item> 
     <name>c</name> 
     <desc>x</desc> 
    </item> 
    </items> 
</root>""" 

def getNodes = { doc, path -> 
    def nodes = doc 
    path.split("\\.").each { nodes = nodes."${it}" } 
    return nodes 
} 

def resource = new XmlSlurper().parseText(xml) 
def xpaths = ['/root/element1','/root/items/item/name'] 

xpaths.each { xpath -> 
    def trimXPath = xpath.replace("/root/", "").replace("/",".") 
    println "xpath = ${trimXPath}" 
    getNodes(resource, trimXPath).each { println it } 
}