Cómo acceder a Checkbox desde VBA en Excel 2007

Question

Al agregar una casilla de verificación, ¿cómo se accede al valor de VBA?

• En Excel 2007, en la cinta de desarrollador
• Insertar, controles de formulario de casilla de verificación
• Renombrado casilla de verificación para chkMyCheck
• Agregado macro para casilla de verificación, que ahora tiene el módulo 1 con chkMyCheck_Clicked

Todos los siguientes fallan

Sheets("Sheet1").chkMyCheck.Checked 
Sheets("Sheet1").chkMyCheck.Value 
Sheets("Sheet1").Shapes("chkMyCheck").Checked 
Sheets("Sheet1").Shapes("chkMyCheck").Value 
Sheet1.chkMyCheck.Checked 
Sheet1.chkMyCheck.Value 

Sheet1.Shapes ("chkMyCheck") parece encontrar el objeto, pero no expone ninguna propiedad que parezca probable para devolver el estado comprobado.

Answer 1

lo descubrió

If Sheet1.Shapes("chkMyCheck").ControlFormat.Value = xlOn Then 
..... 

Answer 2

Una manera:

Dim oCheck As Object 
Set oCheck = Sheet1.CheckBoxes("chkMyCheck") 
MsgBox (oCheck.Value = xlOn) 

Editar: aquí hay otro método - tal vez éste funcionará para usted ...

Sub Tester2() 
    Dim sh As Shape 
    For Each sh In Sheet1.Shapes 
     If sh.Type = msoFormControl Then 
      If sh.FormControlType = xlCheckBox Then 
       Debug.Print sh.Name & "=" & sh.ControlFormat.Value 
      End If 
     End If 
    Next sh 
End Sub 

Answer 3

Para completar, si está utilizando una casilla de verificación ActiveX en lugar de una casilla de verificación normal, la sintaxis es

If Sheet1.Shapes("chkMyCheck").OLEFormat.Object.Object.Value Then 
... 

encontrado usando la ventana locales y un conjunto variable a la forma -

Dim shp as Shape 
Set shp = Sheet1.Shapes("chkMyCheck") 
Stop