El uso de RAISERROR no funciona en SQL Server 2005?

Question

Tengo el siguiente código a continuación:

BEGIN TRY 

    BEGIN TRANSACTION 
     -- DO SOMETHIING 

    COMMIT TRAN 

END TRY 
BEGIN CATCH 
    IF(@@TRANCOUNT > 0) 
    ROLLBACK TRANSACTION 

    RAISERROR(ERROR_MESSAGE(), ERROR_SEVERITY(), ERROR_STATE()) --ERROR: Incorrect syntax near 'ERROR_MESSAGE'. 

END CATCH 

Sin embargo, la instrucción RAISERROR no está funcionando. ¿Qué está mal en la declaración de error de aumento?

Answer 1

RAISERROR sigue las mismas reglas que cualquier otra llamada de procedimiento almacenado. Los parámetros pasados ​​deben ser una constante o una variable. No puede pasar una función directamente como un parámetro. Consulte Executing Stored Procedures para obtener documentación sobre esto.

/* Demo Code - Functions accept functions as parameters 
       while stored procedures do not    */ 

create function dbo.fnDayOfWeek 
    (@date datetime) 
    returns int 
as 
begin 
    declare @x int 
    set @x = DATEPART(day,@date) 
    return (@x) 
end 
go 

/* Both statements are successful */ 
select dbo.fnDayOfWeek('2010-08-06') 
go 
select dbo.fnDayOfWeek(GETDATE()) 
go 

drop function dbo.fnDayOfWeek 
go 

create procedure DayOfWeek 
    @date datetime 
as 
begin 
    select DATEPART(day,@date) 
end 
go 

/* First call succeeds, second fails */ 
exec DayOfWeek @date = '2010-08-06' 
go 
exec DayOfWeek @date = getdate() 
go 

drop procedure DayOfWeek 
go 

Answer 2

error se produce porque directamente utilizando la función de RaiseError manera de evitar esta prueba el código de abajo Prueba esto está trabajando para mí

BEGIN CATCH 
    DECLARE @ErrorMessage NVARCHAR(4000); 
    DECLARE @ErrorSeverity INT; 
    DECLARE @ErrorState INT; 

    SELECT 
     @ErrorMessage = ERROR_MESSAGE(), 
     @ErrorSeverity = ERROR_SEVERITY(), 
     @ErrorState = ERROR_STATE(); 

    RAISERROR (@ErrorMessage, -- Message text. 
       @ErrorSeverity, -- Severity. 
       @ErrorState -- State. 
       ); 
END CATCH;