¿Cómo enviar un correo electrónico al destinatario con diéresis en el nombre de dominio?

Question

En mi aplicación, tengo que enviar un correo electrónico al destinatario que tiene umlauts en el nombre de dominio. Ejemplo: "test@äöü.test.com"

estoy usando la etiqueta CFMAIL y yo estoy poniendo dicho error: "definición no válido para el atributo de correo en la etiqueta" "definición de Dirección no válida de correo electrónico (test@äöü.test.com) "

¿Hay alguna forma de enviar correos electrónicos a dichos destinatarios en coldfusion?

Answer 1

¡Incluso hay una solución más fácil! Por qué no utilizar los oráculos construida en clase: http://download.oracle.com/javase/6/docs/api/java/net/IDN.html#toUnicode(java.lang.String)

Entonces sólo tiene que hacer esto (el ejemplo muestra de punycode a Unicode):

<cfset strUrl = "xn--land-poa.se" /> 

<!--- Create a Java URL. ---> 
<cfset jUrl = CreateObject("java", "java.net.IDN").toUnicode(strUrl) /> 

<cfoutput> 
#jUrl# 

deseados, sin tener que descargar nada !

Answer 2

No soy experto en I18N pero estaba lo suficientemente intrigado como para investigar y llegar a la siguiente solución.

El problema es esencialmente cómo enviar correo a Nombres de dominio internacionalizados (IDN), es decir, aquellos que contienen caracteres no ASCII. Los IDN son válidos hoy en día, pero no son reconocidos por muchos sistemas, incluido Java (y, por lo tanto, ColdFusion, que usa la validación de Java para campos de direcciones CFMAIL, de ahí el error que está viendo).

Para que un sistema reconozca un IDN, debe convertirse a un formato ASCII llamado Punycode. Por ejemplo müller.org necesita ser convertida a xn--mller-kva.org

LibIdn es una biblioteca de Java sistema operativo que va a hacer esto y el código siguiente muestra cómo puede conectarlo a CF usando Mark Mandel's JavaLoader.

<cffunction name="convertIdnToAscii" returntype="string" output="false"> 
    <cfargument name="domain" type="string" required="true"> 
    <cfscript> 
     var local = {}; 
     // these paths assume the JavaLoader folder and the libidn-1.22.jar are in the same folder as the cfm template. 
     local.javaLoaderPath = "javaLoader.JavaLoader"; 
     local.idnLibPath = ExpandPath("libidn-1.22.jar"); 
     // convert the IDN lib path to an array which is what JavaLoader expects 
     local.libPathArray = [ local.idnLibPath ]; 
     //load the IDN Lib 
     loader = CreateObject("component",local.javaLoaderPath).init(local.libPathArray); 
     // create an instance of the IDN lib 
     local.idn = loader.create("gnu.inet.encoding.IDNA").init(); 
     // convert the domain name 
     return local.idn.toASCII(arguments.domain); 
    </cfscript> 
</cffunction> 

<cffunction name="convertIdnAddress" returntype="string" output="false"> 
    <cfargument name="address" type="string" required="true"> 
    <cfscript> 
     var local = {}; 
     local.domain = GetToken(arguments.address,2,"@"); 
     local.converted = convertIdnToAscii(local.domain); 
     return Replace(arguments.address,local.domain,local.converted); 
    </cfscript> 
</cffunction> 

<!--- Loop over a list of addresses and convert them if necessary ---> 
<cfset processedAddresses = []> 
<cfloop list="test@äöü.test.com,test@example.com" index="address"> 
    <cfif(NOT IsValid("email",address))> 
     <cfset address = convertIdnAddress(address)> 
    </cfif> 
    <cfmail server="0.0.0.0" from="sender@mydomain.com" to="#address#" subject="test">Message</cfmail> 
    <cfset ArrayAppend(processedAddresses,address)> 
</cfloop> 
<cfdump var="#processedAddresses#"> 

Esto enviará correos electrónicos (2 a un servidor de correo inexistente) y volcar las direcciones convertidos:

test@xn--4ca0bs.test.com

test@example.com

Notas:

1. para obtener el archivo jar libidn, descargar y extraer el alquitrán y buscar en el directorio de Java
2. Lo anterior supone que el paquete libidn y el paquete JavaLoader se encuentran en la misma carpeta que la plantilla que contiene el código CF
3. Lo anterior debería funcionar en CF8 y superior, aunque solo lo he probado en CF9.
4. Tenga en cuenta que no se manejan errores para las direcciones que pueden ser inválidas por razones distintas a las que contienen un IDN.