zsh alias expansion

Question

¿Es posible configurar zsh para expandir los alias globales durante la finalización de pestañas? Por ejemplo, tengo los alias comunes:

alias -g '...'='../..' 
alias -g '....'='../../..' 

pero cuando escribo, por ejemplo, cd .../some<tab> que no se expandirá a cd .../something o cd ../../something. En consecuencia, con frecuencia no utilizaré estos prácticos alias porque son incompatibles con la finalización de pestañas.

Answer 1

Soy un usuario de Mikael Magnusson de rationalise-dot. Desde mi zshrc:

# This was written entirely by Mikael Magnusson (Mikachu) 
# Basically type '...' to get '../..' with successive .'s adding /.. 
function rationalise-dot { 
    local MATCH # keep the regex match from leaking to the environment 
    if [[ $LBUFFER =~ '(^|/| |  |'$'\n''|\||;|&)\.\.$' ]]; then 
     LBUFFER+=/ 
     zle self-insert 
     zle self-insert 
    else 
     zle self-insert 
    fi 
} 
zle -N rationalise-dot 
bindkey . rationalise-dot 
# without this, typing a . aborts incremental history search 
bindkey -M isearch . self-insert 

Answer 2

Intenta buscar zsh abreviaturas. Te permiten ingresar una "abreviación" que automáticamente se reemplaza con su forma completa cuando presionas una tecla mágica como el espacio. Entonces puede crear uno que cambie ...<SPACE> a ../...

Por ejemplo, esto es lo que necesita en su perfil:

typeset -A abbrevs 
abbrevs=(
     "..." "../.." 
     "...." "../../.."   
) 

#create aliases for the abbrevs too 
for abbr in ${(k)abbrevs}; do 
    alias -g $abbr="${abbrevs[$abbr]}" 
done 

my-expand-abbrev() { 
    local MATCH 
    LBUFFER=${LBUFFER%%(#m)[_a-zA-Z0-9]#} 
    LBUFFER+=${abbrevs[$MATCH]:-$MATCH} 
    zle self-insert 
} 

bindkey " " my-expand-abbrev