¿Cómo puedo marcar/resaltar líneas duplicadas en el editor VI?

Question

¿Cómo harías para marcar todas las líneas en un búfer que son duplicados exactos de otras líneas? Al marcarlos, me refiero a destacarlos o agregar un personaje o algo. Quiero mantener el orden de las líneas en el búfer.

Antes:

foo 
bar 
foo 
baz 

Después:

foo* 
bar 
foo* 
baz 

Answer 1

Como ex de una sola línea:

:syn clear Repeat | g/^\(.*\)\n\ze\%(.*\n\)*\1$/exe 'syn match Repeat "^' . escape(getline('.'), '".\^$*[]') . '$"' | nohlsearch 

Este utiliza el grupo Repeat para resaltar las repetidas líneas.

Descomponiéndola:

• syn clear Repeat :: eliminar cualquier encontrado previamente repeticiones
• g/^\(.*\)\n\ze\%(.*\n\)*\1$/ :: para cualquier línea que se repite más adelante en el archivo
  • la expresión regular
    • ^\(.*\)\n :: una línea completa
    • \ze :: final del partido - verificar que el resto del patrón, pero no consumen el texto coincidente (búsqueda positiva hacia delante)
    • \%(.*\n\)* :: cualquier número de líneas completas
    • \1$ :: una repetición de la línea completa emparejado línea completa
  • exe 'syn match Repeat "^' . escape(getline('.'), '".\^$*[]') . '$"' :: añadir líneas completas que coincidan con este al grupo Repeat sintaxis
    • exe :: ejecutar la cadena dada como un comando ex
    • getline('.') :: el contenido de la línea actual igualada por g//
    • escape(..., '".\^$*[]') :: escapar los caracteres dados con barras invertidas para hacer una expresión regular de fiar
    • syn match Repeat "^...$" :: añadir la cadena dada al grupo Repeat sintaxis
• nohlsearch :: eliminar destacando de la búsqueda realizada por g//

método no regex

de Justin es probablemente más rápido:

function! HighlightRepeats() range 
    let lineCounts = {} 
    let lineNum = a:firstline 
    while lineNum <= a:lastline 
    let lineText = getline(lineNum) 
    if lineText != "" 
     let lineCounts[lineText] = (has_key(lineCounts, lineText) ? lineCounts[lineText] : 0) + 1 
    endif 
    let lineNum = lineNum + 1 
    endwhile 
    exe 'syn clear Repeat' 
    for lineText in keys(lineCounts) 
    if lineCounts[lineText] >= 2 
     exe 'syn match Repeat "^' . escape(lineText, '".\^$*[]') . '$"' 
    endif 
    endfor 
endfunction 

command! -range=% HighlightRepeats <line1>,<line2>call HighlightRepeats() 

Answer 2

Ejecutar a través de la lista una vez, crea un mapa de cada cuerda y cuántas veces se produce. Vuelva a recorrerlo y agregue su * a cualquier cadena que tenga un valor de más de uno en el mapa.

Answer 3

Probar:

:%s:^\(.\+\)\n\1:\1*\r\1: 

Espero que esto funcione.

Actualización: próximo intento.

:%s:^\(.\+\)$\(\_.\+\)^\1$:\1\r\2\r\1*: 

Answer 4

Por qué no usar:

V* 

en modo normal.

Simplemente busca en todos los partidos de línea actual, destacando así ellos (si el ajuste está habilitado, lo que creo que es el valor por defecto) Además, a continuación, puede utilizar

n 

Para navegar a través de los partidos

Answer 5

Ninguna de las respuestas anteriores dio para mí, así que esto es lo que hago:

1. Ordenar el archivo con :sort
2. ejecutar el comando :g/^\(.*\)$\n\1$/p

Answer 6

1. :sort y guardarlo en file1.
2. :sort u y guárdelo en file2.
3. gvimdiff o tkdiff los dos archivos.