de Jeb es un montón de diversión, pero es muy dependiente de la longitud del texto que se añade o se elimina. Creo que los resultados contrarios a la intuición son lo que quiso decir cuando dijo "Si lo modificas antes, entonces comenzará a hacer cosas extrañas (repetir comandos, etc.)".
Modifiqué el código de jeb para mostrar cómo se puede modificar libremente el código dinámico de longitud variable al comienzo de un archivo por lotes en ejecución, siempre que el relleno apropiado esté en su lugar. Toda la sección dinámica se reemplaza por completo con cada iteración. Cada línea dinámica tiene el prefijo ; que no interfiere. Esto permite convenientemente FOR /F quitar el código dinámico debido a la opción implícita EOL=;.
En lugar de buscar un número de línea particular, busco un comentario específico para ubicar dónde comienza el código dinámico. Esto es más fácil de mantener.
Utilizo líneas de signos iguales para rellenar el código de forma inofensiva y permitir la expansión y la contracción. Se puede usar cualquier combinación de los siguientes caracteres: coma, punto y coma, igual, espacio, pestaña y/o nueva línea. (Por supuesto, el relleno no puede comenzar con un punto y coma.) Los signos de igual dentro de los paréntesis permiten la expansión del código. Los signos de igual después del paréntesis permiten la contracción del código.
Tenga en cuenta que FOR /F elimina las líneas vacías.Esta limitación se puede superar mediante el uso de FINDSTR para prefijar cada línea con el número de línea y luego quitar el prefijo dentro del ciclo. Pero el código adicional ralentiza las cosas, por lo que no vale la pena hacerlo a menos que el código dependa de líneas en blanco.
@echo off
setlocal DisableDelayedExpansion
echo The starting filesize is %~z0
:loop
echo ----------------------
::*** Start of dynamic code ***
;set value=1
::*** End of dynamic code ***
echo The current value=%value%
::
::The 2 lines of equal signs amount to 164 bytes, including end of line chars.
::Putting the lines both within and after the parentheses allows for expansion
::or contraction by up to 164 bytes within the dynamic section of code.
(
call :changeBatch
==============================================================================
==============================================================================
)
================================================================================
================================================================================
set /p "quit=Enter Q to quit, anything else to continue: "
if /i "%quit%"=="Q" exit /b
goto :loop
:changeBatch
(
for /f "usebackq delims=" %%a in ("%~f0") do (
echo %%a
if "%%a"=="::*** Start of dynamic code ***" (
setlocal enableDelayedExpansion
set /a newValue=value+1, extra=!random!%%9
echo ;set value=!newValue!
for /l %%n in (1 1 !extra!) do echo ;echo extra line %%n
endlocal
)
)
) >"%~f0.tmp"
::
::The 2 lines of equal signs amount to 164 bytes, including end of line chars.
::Putting the lines both within and after the parentheses allows for expansion
::or contraction by up to 164 bytes within the dynamic section of code.
(
move /y "%~f0.tmp" "%~f0" > nul
==============================================================================
==============================================================================
)
================================================================================
================================================================================
echo The new filesize is %~z0
exit /b
Los trabajos anteriores, pero las cosas son mucho más fáciles si el código dinámico se mueve a una subrutina al final del archivo. El código puede expandirse y contraerse sin limitación, y sin la necesidad de relleno. FINDSTR es mucho más rápido que FOR/F para eliminar la parte dinámica. Las líneas dinámicas pueden ser prefijadas con un punto y coma (incluidas las etiquetas). Luego, la opción FINDSTR/V se usa para excluir líneas que comienzan con un punto y coma y el nuevo código dinámico puede simplemente anexarse.
@echo off
setlocal DisableDelayedExpansion
echo The starting filesize is %~z0
:loop
echo ----------------------
call :dynamicCode1
call :dynamicCode2
echo The current value=%value%
call :changeBatch
set /p "quit=Enter Q to quit, anything else to continue: "
if /i "%quit%"=="Q" exit /b
goto :loop
:changeBatch
(
findstr /v "^;" "%~f0"
setlocal enableDelayedExpansion
set /a newValue=value+1, extra=!random!%%9
echo ;:dynamicCode1
echo ;set value=!newValue!
echo ;exit /b
echo ;
echo ;:dynamicCode2
for /l %%n in (1 1 !extra!) do echo ;echo extra line %%n
echo ;exit /b
endlocal
) >"%~f0.tmp"
move /y "%~f0.tmp" "%~f0" > nul
echo The new filesize is %~z0
exit /b
;:dynamicCode1
;set value=33
;exit /b
;
;:dynamicCode2
;echo extra line 1
;exit /b
Usted gotta love respuestas tan rápido. Ya comenzó a ejecutar el lote> publicó una pregunta> obtuvo una respuesta> editó su archivo antes de la ejecución completada. –
También tenga en cuenta que cuando se elimine o se cambie el nombre del archivo por lotes, en el momento en que finalice la instrucción actual se generará un error: "No se puede encontrar el archivo por lotes". –