Uso de instrucciones condicionales dentro de 'esperar'

Question

Necesito automatizar el registro en una sesión de TELNET usando espero, pero tengo que ocuparme de múltiples contraseñas para el mismo nombre de usuario.

Aquí está el flujo Necesito crear:

1. sesión TELNET abierto a una IP
2. Enviar nombre de usuario
3. Enviar contraseña
4. contraseña incorrecta? Enviar el mismo nombre de usuario nuevo, entonces una contraseña diferente
5. Debería haber iniciado la sesión en el éxito en este punto ...

Por lo que vale la pena, esto es lo que tengo hasta ahora:

#!/usr/bin/expect 
spawn telnet 192.168.40.100 
expect "login:" 
send "spongebob\r" 
expect "password:" 
send "squarepants\r" 
expect "login incorrect" { 
    expect "login:" 
    send "spongebob\r" 
    expect "password:" 
    send "rhombuspants\r" 
} 
expect "prompt\>" { 
    send_user "success!\r" 
} 
send "blah...blah...blah\r" 

No hace falta decir que esto no funciona, y tampoco se ve muy bonito. De mis aventuras con Google espera parece ser algo así como un arte oscuro. Gracias de antemano a cualquier persona por su ayuda en el asunto!

Answer 1

Tiene que recomendar el libro Exploring Expect para todos los programadores esperables - invaluable.

He reescrito el código: (no probado)

proc login {user pass} { 
    expect "login:" 
    send "$user\r" 
    expect "password:" 
    send "$pass\r" 
} 

set username spongebob 
set passwords {squarepants rhombuspants} 
set index 0 

spawn telnet 192.168.40.100 
login $username [lindex $passwords $index] 
expect { 
    "login incorrect" { 
     send_user "failed with $username:[lindex $passwords $index]\n" 
     incr index 
     if {$index == [llength $passwords]} { 
      error "ran out of possible passwords" 
     } 
     login $username [lindex $passwords $index] 
     exp_continue 
    } 
    "prompt>" 
} 
send_user "success!\n" 
# ... 

exp_continue bucles de nuevo al principio del bloque de esperar - es como una declaración "rehacer".

Tenga en cuenta que send_user termina con \n no \r

Usted no tiene que escapar el carácter > en su mensaje: no es especial para Tcl.

Answer 2

Si conoce los identificadores de usuario y las contraseñas, entonces también debe saber qué pares de ID de usuario/contraseña están alineados con qué sistemas. Creo que sería mejor mantener un mapa de qué par de ID de usuario/contraseña va con qué sistema luego extraer esa información y simplemente usar la correcta.

Por lo tanto - ya que, obviamente, no le gusta mi consejo, entonces le sugiero que busque en el wikipedia page y poner en práctica un procedimiento que devuelve 0 si tiene éxito y 1 si los tiempos de expectativa a cabo. Eso le permitirá detectar cuándo falló la contraseña suministrada, la esperanza de espera se agotó y volver a intentar. Si esto es útil, puedes eliminar tu voto negativo ahora que lo he editado.

En retrospectiva, es probable que desee hacer esto junto con el mapa de todos modos, ya que es posible que desee detectar un inicio de sesión fallido si se cambia la contraseña.

Answer 3

Con un poco de golpes encontré una solución. Resulta que esperar que utiliza una sintaxis TCL que no estoy del todo familiarizado con:

#!/usr/bin/expect 
set pass(0) "squarepants" 
set pass(1) "rhombuspants" 
set pass(2) "trapezoidpants" 
set count 0 
set prompt "> " 
spawn telnet 192.168.40.100 
expect { 
    "$prompt" { 
    send_user "successfully logged in!\r" 
    } 
    "password:" { 
    send "$pass($count)\r" 
    exp_continue 
    } 
    "login incorrect" { 
    incr count 
    exp_continue 
    } 
    "username:" { 
    send "spongebob\r" 
    exp_continue 
    } 
} 
send "command1\r" 
expect "$prompt" 
send "command2\r" 
expect "$prompt" 
send "exit\r" 
expect eof 
exit 

espero que esto sea útil para otros.