Cómo contar elementos con el mismo valor de atributo

Question

Estoy seguro de que este es fácil, pero simplemente no veo la madera para los árboles.

estoy teniendo un XML que se parecen a esto:

<root> 
    <profil> 
     <e1 a="2">1</e1> 
     <m1 a="3">1</m1> 
     <e2 a="4">1</e2> 
     <m2 a="5">1</m2> 
    </profil> 
    <profil> 
     <e1 a="5">1</e1> 
     <m1 a="3">1</m1> 
     <e2 a="4">1</e2> 
     <m2 a="4">1</m2> 
    </profil> 
    <profil> 
     <e1 a="7">1</e1> 
     <m1 a="7">1</m1> 
     <e2 a="4">1</e2> 
     <m2 a="2">1</m2> 
    </profil> 
</root> 

Ahora quiero saber cuántos/m */@ a es igual a E */@ A por/profil. Así me ocurrió con la siguiente XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
    <xsl:template match="*"> 
     <xsl:element name="root"> 
      <xsl:for-each select="/root/profil"> 
       <xsl:element name="count"> 
        <xsl:value-of select="count(*[contains(name(), 'm') and ./@a = //*[contains(name(),'e')]/@a])"/> 
       </xsl:element> 
      </xsl:for-each> 
     </xsl:element> 
    </xsl:template> 
</xsl:stylesheet> 

Pero el resultado es falso:

<root> 
    <count>1</count> 
    <count>1</count> 
    <count>2</count> 
</root> 

Cabe

<root> 
    <count>0</count> 
    <count>1</count> 
    <count>1</count> 
</root> 

¿Alguien tiene una sugerencia de lo que estoy haciendo mal ?

Answer 1

Reemplazar el XPath con la correcta, que es:

<xsl:value-of select="count(*[substring(name(),1,1)='m' 
     and ./@a = ../*[substring(name(),1,1)='e']/@a])"/> 

He usado substring para que coincida con el primer carácter de atributo en lugar de contains que coincide con cualquier carácter en una cadena.

Answer 2

creo que esto es lo que necesita

count(*[contains(name(), 'm') and (@a = parent::*/*[contains(name(),'e')]/@a)]) 

El uso de este en su XSLT

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
    <xsl:template match="*"> 
     <xsl:element name="root"> 
      <xsl:for-each select="/root/profil"> 
       <xsl:element name="count"> 
        <xsl:value-of select="count(*[contains(name(), 'm') and (@a = parent::*/*[contains(name(),'e')]/@a)])"/> 
       </xsl:element> 
      </xsl:for-each> 
     </xsl:element> 
    </xsl:template> 
</xsl:stylesheet> 

produce la salida deseada

<root> 
    <count>0</count> 
    <count>1</count> 
    <count>1</count> 
</root> 

Answer 3

Uso (con nodo actual cualquier profil elemento):

count(*[starts-with(name(),'m') 
     and 
     @a = ../*[starts-with(name(),'e')]/@a 
     ] 
    ) 

Y el código XSLT completa:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="profil"> 
    <count> 
    <xsl:value-of select= 
    "count(*[starts-with(name(),'m') 
      and 
      @a = ../*[starts-with(name(),'e')]/@a 
      ] 
     ) 
    "/> 
    </count> 
</xsl:template> 
</xsl:stylesheet> 

cuando se aplica en el documento XML proporcionado:

<root> 
    <profil> 
     <e1 a="2">1</e1> 
     <m1 a="3">1</m1> 
     <e2 a="4">1</e2> 
     <m2 a="5">1</m2> 
    </profil> 
    <profil> 
     <e1 a="5">1</e1> 
     <m1 a="3">1</m1> 
     <e2 a="4">1</e2> 
     <m2 a="4">1</m2> 
    </profil> 
    <profil> 
     <e1 a="7">1</e1> 
     <m1 a="7">1</m1> 
     <e2 a="4">1</e2> 
     <m2 a="2">1</m2> 
    </profil> 
</root> 

produce el, resultado correcto deseada:

<count>0</count> 
<count>1</count> 
<count>1</count>