Destruir objeto durante el evento invocado por dicho objeto

Question

Tengo un botón. Su evento OnClick llama a un procedimiento que destruye el botón, pero luego el "hilo" desea volver al evento OnClick y aparece una infracción de acceso.

¡Estoy completamente perplejo!

Answer 1

Debe destruir el botón después de que todo su código haya terminado de ejecutarse. La forma estándar de hacer esto es publicar un mensaje definido por el usuario en el formulario y darle al formulario un método de mensaje que lo interpretará. Por ejemplo:

unit Unit1; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, StdCtrls; 

const 
    WM_KILLCONTROL = WM_USER + 1; 

type 

    TForm1 = class(TForm) 
    Button1: TButton; 
    procedure Button1Click(Sender: TObject); 
    private 
    { Private declarations } 
    procedure KillControl(var message: TMessage); message WM_KILLCONTROL; 
    public 
    { Public declarations } 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

{ TForm1 } 

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    PostMessage(self.Handle, WM_KILLCONTROL, 0, integer(Button1)) 
end; 

procedure TForm1.KillControl(var message: TMessage); 
var 
    control: TControl; 
begin 
    control := TObject(message.LParam) as TControl; 
    assert(control.Owner = self); 
    control.Free; 
end; 

end. 

Esto funciona porque el mensaje se pone en la cola de mensajes de Windows y no sale hasta que todo antes de que (incluyendo el mensaje Haga clic en el botón que se encuentra actualmente respondiendo a) se haya completado el procesamiento.

Answer 2

En su lugar, podría simplemente activar un temporizador en el evento OnClick, luego escribir el evento Timer primero para deshabilitar el temporizador y luego llamar al procedimiento que está llamando actualmente desde el evento OnClick. Configure el temporizador desactivado y con un corto intervalo de tiempo.