Encontrar la diferencia entre 2 fechas en xslt

Question

¿Hay alguna manera de encontrar la diferencia en días entre 2 fechas en xslt? Si es así, ¿puedes señalarme en la dirección correcta? Estoy recibiendo fechas en el formato de mm/dd/aaaa.

Answer 1

uso de XSLT 2.0 (XPath 2.0) para este:

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:my="my:my"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="/"> 
    <xsl:variable name="vDate1" 
     select="my:dateFromUsDate(/*/d1)"/> 
    <xsl:variable name="vDate2" 
     select="my:dateFromUsDate(/*/d2)"/> 

    <xsl:sequence select= 
    "($vDate1 - $vDate2) div xs:dayTimeDuration('P1D')"/> 
</xsl:template> 

<xsl:function name="my:dateFromUsDate" as="xs:date"> 
    <xsl:param name="pUsDate" as="xs:string"/> 

    <xsl:sequence select= 
    "xs:date(concat(substring($pUsDate,7,4), 
        '-', 
        substring($pUsDate,1,2), 
        '-', 
        substring($pUsDate,4,2) 
       ) 
     ) 
    "/> 
</xsl:function> 
</xsl:stylesheet> 

cuando se aplica esta transformación en el siguiente documento XML:

<t> 
<d1>04/06/2011</d1> 
<d2>01/11/2010</d2> 
</t> 

el, resultado correcto deseado (la diferencia es 450 días) se produce:

450 

Answer 2

Una alternativa más agradable (y más corta) para XSLT 1.0 es calcular las fechas Julianas equivalentes y restarlas.

Plantilla:

<xsl:template name="calculate-julian-day"> 
    <xsl:param name="year"/> 
    <xsl:param name="month"/> 
    <xsl:param name="day"/> 

    <xsl:variable name="a" select="floor((14 - $month) div 12)"/> 
    <xsl:variable name="y" select="$year + 4800 - $a"/> 
    <xsl:variable name="m" select="$month + 12 * $a - 3"/> 

    <xsl:value-of select="$day + floor((153 * $m + 2) div 5) + $y * 365 + floor($y div 4) - floor($y div 100) + floor($y div 400) - 32045"/> 

Uso:

<xsl:variable name="dateInv" select="'20120406'" /> 
<xsl:call-template name="calculate-julian-day"> 
    <xsl:with-param name="year" select="substring($date,1,4)"/> 
    <xsl:with-param name="month" select="substring($date,5,2)"/> 
    <xsl:with-param name="day" select="substring($date,7,2)"/> 
</xsl:call-template> 

Repita para la segunda fecha y tendrá dos números enteros. Entonces, simplemente restarlos.

Answer 3

Esto podría hacerse fácilmente utilizando la siguiente expresión:

days-from-duration(xs:date('yyyy-MM-dd')-xs:date('yyyy-MM-dd')) 

Por ejemplo:

days-from-duration(xs:date('2012-06-30')-xs:date('2012-06-18')) 

daré resultado de