Comando T-SQL STOP o ABORT en SQL Server

Question

¿Hay un comando en Microsoft SQL Server T-SQL que indique a la secuencia de comandos que pare el procesamiento? Tengo un script que quiero guardar para archivarlo, pero no quiero que nadie lo ejecute.

Answer 1

Una solución alternativa podría ser para alterar el flujo de ejecución de la secuencia de comandos mediante la instrucción GOTO ...

DECLARE @RunScript bit; 
SET @RunScript = 0; 

IF @RunScript != 1 
BEGIN 
RAISERROR ('Raise Error does not stop processing, so we will call GOTO to skip over the script', 1, 1); 
GOTO Skipper -- This will skip over the script and go to Skipper 
END 

PRINT 'This is where your working script can go'; 
PRINT 'This is where your working script can go'; 
PRINT 'This is where your working script can go'; 
PRINT 'This is where your working script can go'; 

Skipper: -- Don't do nuttin! 

Advertencia! La muestra anterior se derivó de un ejemplo que obtuve de Merrill Aldrich. Antes de implementar ciegamente la declaración GOTO, le recomiendo que lea su tutorial en Flow control in T-SQL Scripts.

Answer 2

Por qué no simplemente añadir lo siguiente al comienzo de la secuencia de comandos

PRINT 'INACTIVE SCRIPT' 
RETURN 

Answer 3

intente ejecutar esto como una secuencia de comandos TSQL

SELECT 1 
RETURN 
SELECT 2 
SELECT 3 

El retorno termina la ejecución.

RETURN (Transact-SQL)

Sale incondicionalmente de una consulta o procedimiento. RETURN es inmediato y se completó y se puede usar en cualquier punto para salir de un bloque de instrucciones de procedimiento, lote o . Las declaraciones que siguen RETORNO no se ejecutan.

Answer 4

Para solucionar el problema RETURN/GO, puede poner RAISERROR ('Oi! Stop!', 20, 1) WITH LOG en la parte superior.

Esto cerrará la conexión del cliente según RAISERROR on MSDN.

El muy grande inconveniente es que tienes que ser administrador de sistemas para utilizar la gravedad 20.

Editar:

una simple demostración para contrarrestar el comentario de Jersey Tipo ...

RAISERROR ('Oi! Stop!', 20, 1) WITH LOG 
SELECT 'Will not run' 
GO 
SELECT 'Will not run' 
GO 
SELECT 'Will not run' 
GO 

Answer 5

n , no hay uno - usted tiene un par de opciones:

1. Envuelve todo el script en un bloque if/end grande que simplemente se asegura que no sea verdadero (es decir "si 1 = 2 begin" - esto solo funcionará, sin embargo, si el script no incluye ninguna declaración GO (ya que estos indican un nuevo lote)

2. Use la declaración return en la parte superior (nuevamente, limitada por el lote) separadores)

3. utilice un enfoque basado en la conexión, lo que garantizará la no ejecución de todo el guión (de conexión completo para ser más exactos) - usar algo así como un 'SET PARSEONLY ON' o 'SET NOEXEC ON' en la parte superior de la secuencia de comandos. Esto asegurará que todas las declaraciones en la conexión (o hasta que dicha declaración establecida se desactive) no se ejecutarán y en su lugar solo se analizarán/compilarán.

4. Utilice un bloque de comentarios para comentar todo el script (es decir/ * Y * /)

EDIT: Demostración de que la declaración de 'retorno' es lote específico - en cuenta que seguirá viendo conjuntos de resultados después de los rendimientos:

select 1 
return 
go 
select 2 
return 
select 3 
go 
select 4 
return 
select 5 
select 6 
go 

Answer 6

A pesar de su muy descripción explícita y contundente, RETORNO no funcionó para mí dentro de un procedimiento almacenado (para omitir la ejecución posterior). Tuve que modificar la lógica de la condición. Que sucede tanto en SQL 2008, 2008 R2:

create proc dbo.prSess_Ins 
(
    @sSessID varchar(32) 
, @idSess  int out 
) 
as 
begin 
    set nocount on 

    select @id= idSess 
     from tbSess 
     where sSessID = @sSessID 

    if @idSess > 0 return -- exit sproc here 

    begin tran 
     insert tbSess (sSessID) values (@sSessID) 
     select @idSess= scope_identity() 
    commit 
end 

tuvo que ser cambiado en:

if @idSess is null 
    begin 
     begin tran 
      insert tbSess (sSessID) values (@sSessID) 
      select @idSess= scope_identity() 
     commit 
    end 

Descubierto como resultado de la búsqueda de filas duplicadas. Las IMPRESIONES de depuración confirmaron que @idSess tenía un valor mayor que cero en la verificación IF. ¡RETORNO no interrumpió la ejecución!

Answer 7

RAISERROR con gravedad 20 se reportará como un error en el Visor de eventos.

Puede usar SET PARSEONLY ON; (o NOEXEC). Al final del script, usa GO SET PARSEONLY OFF;

SET PARSEONLY ON; 
-- statement between here will not run 

SELECT 'THIS WILL NOT EXEC'; 

GO 
-- statement below here will run 

SET PARSEONLY OFF; 

Answer 8

Aquí hay una manera algo complicada de hacerlo que funciona con GO-batches, mediante el uso de una variable "global".

if object_id('tempdb..#vars') is not null 
begin 
    drop table #vars 
end 

create table #vars (continueScript bit) 
set nocount on 
    insert #vars values (1) 
set nocount off 

-- Start of first batch 
if ((select continueScript from #vars)=1) begin 

    print '1' 

    -- Conditionally terminate entire script 
    if (1=1) begin 
    set nocount on 
     update #vars set continueScript=0 
    set nocount off 
    return 
    end 

end 
go 

-- Start of second batch 
if ((select continueScript from #vars)=1) begin 

    print '2' 

end 
go 

Y aquí está la misma idea utilizada con una transacción y un bloque de prueba/captura para cada GO-batch. Usted puede tratar de cambiar las diversas condiciones y/o dejar que se genera un error (división por 0, ver comentarios) para probar cómo se comporta:

if object_id('tempdb..#vars') is not null 
begin 
    drop table #vars 
end 

create table #vars (continueScript bit) 
set nocount on 
    insert #vars values (1) 
set nocount off 

begin transaction; 
    -- Batch 1 starts here 
    if ((select continueScript from #vars)=1) begin 
    begin try 
     print 'batch 1 starts' 

     if (1=0) begin 
     print 'Script is terminating because of special condition 1.' 
     set nocount on 
      update #vars set continueScript=0 
     set nocount off 
     return 
     end 

     print 'batch 1 in the middle of its progress' 

     if (1=0) begin 
     print 'Script is terminating because of special condition 2.' 
     set nocount on 
      update #vars set continueScript=0 
     set nocount off 
     return 
     end 

     set nocount on 
     -- use 1/0 to generate an exception here 
     select 1/1 as test 
     set nocount off 

    end try 
    begin catch 
     set nocount on 
     select 
      error_number() as errornumber 
      ,error_severity() as errorseverity 
      ,error_state() as errorstate 
      ,error_procedure() as errorprocedure 
      ,error_line() as errorline 
      ,error_message() as errormessage; 
     print 'Script is terminating because of error.' 
     update #vars set continueScript=0 
     set nocount off 
     return 
    end catch; 

    end 
    go 

    -- Batch 2 starts here 
    if ((select continueScript from #vars)=1) begin 

    begin try 
     print 'batch 2 starts' 

     if (1=0) begin 
     print 'Script is terminating because of special condition 1.' 
     set nocount on 
      update #vars set continueScript=0 
     set nocount off 
     return 
     end 

     print 'batch 2 in the middle of its progress' 

     if (1=0) begin 
     print 'Script is terminating because of special condition 2.' 
     set nocount on 
      update #vars set continueScript=0 
     set nocount off 
     return 
     end 

     set nocount on 
     -- use 1/0 to generate an exception here 
     select 1/1 as test 
     set nocount off 

    end try 
    begin catch 
     set nocount on 
     select 
      error_number() as errornumber 
      ,error_severity() as errorseverity 
      ,error_state() as errorstate 
      ,error_procedure() as errorprocedure 
      ,error_line() as errorline 
      ,error_message() as errormessage; 
     print 'Script is terminating because of error.' 
     update #vars set continueScript=0 
     set nocount off 
     return 
    end catch; 

    end 
    go 

if @@trancount > 0 begin 
    if ((select continueScript from #vars)=1) begin 
    commit transaction 
    print 'transaction committed' 
    end else begin 
    rollback transaction; 
    print 'transaction rolled back' 
    end 
end 

Answer 9

Sé que la pregunta es antigua y fue contestada correctamente en algunos diferentes maneras pero no hay respuesta como la mía que he usado en situaciones similares. Primera aproximación (muy básico):

IF (1=0) 
BEGIN 
    PRINT 'it will not go there' 
    -- your script here 
END 
PRINT 'but it will here' 

Segundo enfoque:

PRINT 'stop here' 
RETURN 
    -- your script here 
PRINT 'it will not go there' 

puede comprobarlo fácilmente por sí mismo para asegurarse de que se comporta como se esperaba.