¿Cómo puedo ingresar una contraseña usando Perl y reemplazar los caracteres con '*'?

Question

Tengo un script de Perl que requiere que el usuario ingrese una contraseña. ¿Cómo puedo hacer eco solo '*' en lugar del carácter que el usuario escribe, tal como lo escriben?

Estoy usando Windows XP/Vista.

Answer 1

Puedes jugar con Term :: ReadKey. Aquí hay un ejemplo muy simple, con algo de detección de teclas de retroceso y eliminación. Lo probé en Mac OS X 10.5 pero según el ReadKey manual debería funcionar en Windows. El manual indica que en Windows, las lecturas sin bloqueo (ReadKey(-1)) fallarán. Es por eso que estoy usando ReadKey (0) que es básicamente getc (más en getc en el libc manual).

#!/usr/bin/perl                                                 

use strict;                                                  
use warnings;                                                 
use Term::ReadKey;                                                

my $key = 0;                                                 
my $password = "";                                                

print "\nPlease input your password: ";                                           

# Start reading the keys                                              
ReadMode(4); #Disable the control keys                                           
while(ord($key = ReadKey(0)) != 10)                                            
# This will continue until the Enter key is pressed (decimal value of 10)                                  
{                                                    
    # For all value of ord($key) see http://www.asciitable.com/                                     
    if(ord($key) == 127 || ord($key) == 8) {                                         
     # DEL/Backspace was pressed                                            
     #1. Remove the last char from the password                                        
     chop($password);                                              
     #2 move the cursor back by one, print a blank character, move the cursor back by one                             
     print "\b \b";                                               
    } elsif(ord($key) < 32) {                                             
     # Do nothing with these control characters                                        
    } else {                                                 
     $password = $password.$key;                                            
     print "*(".ord($key).")";                                            
    }                                                   
}                                                    
ReadMode(0); #Reset the terminal once we are done                                        
print "\n\nYour super secret password is: $password\n"; 

Answer 2

¿Ha intentado guardar la cadena (para que su programa todavía pueda leerla) y descubra su longitud, luego cree una cadena de la misma longitud, pero solo use '*'?

Answer 3

Debe echar un vistazo a Term::ReadKey o Win32::Console. Puede usar esos módulos para leer los trazos de teclas individuales y emitir '*' o lo que quiera.

Answer 4

En el pasado he usado IO::Prompt para esto.

use IO::Prompt; 
my $password = prompt('Password:', -e => '*'); 
print "$password\n"; 

Answer 5

Si no desea utilizar cualquier paquete ... Sólo para UNIX

system('stty','-echo'); 
chop($password=<STDIN>); 
system('stty','echo'); 

Answer 6

Basándose en el programa de Pierr-Luc, se agregó un cierto control sobre las barras invertidas. Con esto, no puede seguir presionando la barra invertida para siempre:

sub passwordDisplay() { 
    my $password = ""; 
    # Start reading the keys 
    ReadMode(4); #Disable the control keys 
    my $count = 0; 
    while(ord($key = ReadKey(0)) != 10) { 
      # This will continue until the Enter key is pressed (decimal value of 10) 
      # For all value of ord($key) see http://www.asciitable.com/ 
      if(ord($key) == 127 || ord($key) == 8) { 
        # DEL/Backspace was pressed 
        if ($count > 0) { 
          $count--; 
          #1. Remove the last char from the password 
          chop($password); 
          #2 move the cursor back by one, print a blank character, move the cursor back by one 
          print "\b \b"; 
        } 
      } 
      elsif(ord($key) >= 32) { 
        $count++; 
        $password = $password.$key; 
        print "*"; 
      } 
    } 
    ReadMode(0); #Reset the terminal once we are done 
    return $password; 
}